Terraform-중첩 된 맵 반복

Question

google_bigquery_dataset_iam_binding 리소스를 사용하여 Bigquery 데이터 세트에 대한 IAM 바인딩을 만들려고합니다. 요구 사항은 다음 구조의 변수를 사용하여이 리소스 (dataset_id, role, members)의 매개 변수를 읽는 것입니다.

  bq_iam_role_bindings = {
    "member1" = {
      "dataset1" : ["role1","role2", "role5"],
      "dataset2" : ["role3","role2"],
    },
    "member2" = {
      "dataset3" : ["role1","role4"],
      "dataset2" : ["role5"],
    } 
  }

따라서이 변수를 반복하고 각 멤버의 데이터 세트에 할당 된 역할을 가져와야합니다. 여기에서 생성 된 총 리소스는 8 개입니다 (각 구성원, 각 데이터 세트 및 각 역할). 저는 terraform을 처음 접했고 리소스의 맵과 for_each 루프에 대해 간단한 for 루프를 적용하는 방법 만 이해합니다. 내가하려는 일이 어떻게 가능한지 이해하고 싶습니다.

이것은 내가 찾은 가장 가까운 것입니다- 중첩 된 맵에서 값을 읽을 수 있지만 제 경우에도 키를 추출해야하는 테라 폼 변수의 맵 내 맵입니다 . 누구든지 여기에서 도울 수 있습니까?

Answer 1

좀 더 for_each친숙한 객체 목록 으로 재구성 하고 로컬 helper_list.

예를 들면 :

variable "bq_iam_role_bindings" {

  default = {
    "member1" = {
      "dataset1" : ["role1","role2", "role5"],
      "dataset2" : ["role3","role2"],
    },
    "member2" = {
      "dataset3" : ["role1","role4"],
      "dataset2" : ["role5"],
    } 
  }
}

locals {

  helper_list = flatten([for member, value in var.bq_iam_role_bindings:
                 flatten([for dataset, roles in value: 
                           [for role in roles:
                            {"member" = member
                            "dataset" = dataset
                            "role" = role}
                         ]])
                   ])
}

결과 helper_list는 다음과 같습니다.

[
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role1"
  },
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role2"
  },
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role5"
  },
  {
    "dataset" = "dataset2"
    "member" = "member1"
    "role" = "role3"
  },
  {
    "dataset" = "dataset2"
    "member" = "member1"
    "role" = "role2"
  },
  {
    "dataset" = "dataset2"
    "member" = "member2"
    "role" = "role5"
  },
  {
    "dataset" = "dataset3"
    "member" = "member2"
    "role" = "role1"
  },
  {
    "dataset" = "dataset3"
    "member" = "member2"
    "role" = "role4"
  },
]

위의 형식은 작업하기가 훨씬 쉽습니다 for_each. 예 :

resource "google_bigquery_dataset_iam_binding" "reader" {

  for_each =  { for idx, record in local.helper_list : idx => record }

  dataset_id = each.value.dataset
  role       = each.value.role

  members = [
    each.value.member
  ]
}