Группы безопасности Terraform AWS-EC2

Question

Я очень занят, пытаясь узнать больше о Terraform, но у меня есть одна проблема, которую я не знаю, как ее обойти / исправить.

Проблема заключается в следующем: в моем сценарии я создаю экземпляр ec2 (AWS) с парой побочных вещей, например en EIP и группой безопасности из модуля, который все работает нормально. Но я не могу понять, как прикрепить группу безопасности к машине, теперь она создается и все.

Код выглядит следующим образом:

data "aws_ami" "latest" {
  most_recent = true
  owners = [ "self"] 

    filter {
      name = "name"
      values = [ lookup(var.default_ami, var.ami) ]
    }
}

module "aws_security_group" {
  source = "./modules/services/Security groups/"
  server_port = 443
}

resource "aws_instance" "test-ec2deployment" {
  ami                           = data.aws_ami.latest.id
  instance_type                 = var.instance_type
  subnet_id                     = var.subnet_id
  availability_zone             = var.availability_zone
  associate_public_ip_address   = var.public_ip
  
  root_block_device {
    volume_type                 = "gp2"
    volume_size                 = 60
    delete_on_termination       = true
  }
  
   tags = {
    Name                        = "Testserver2viaTerraform"
  }
}

resource "aws_eip" "ip" {
  instance = aws_instance.test-ec2deployment.id
}

resource "aws_eip" "example" {
  vpc = true
}

Выше основной файл, и я загружаю следующий модуль:

resource "aws_security_group" "my-webserver" {
  name        = "webserver"
  description = "Allow HTTP from Anywhere"
  vpc_id      = "vpc-"
  ingress {
    from_port   = 80
    to_port     = 80
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }
  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
  tags = {
    Name = "my-webserver"
    Site = "my-web-site"
  }
}

Последний шаг - прикрепить группу безопасности к машине, но опять же, не знаю, как это сделать. Я читал несколько документов и пытался погуглить, но я не могу найти ответ, или ответ не работает для меня. Надеюсь, вы, ребята, сможете мне помочь.

Спасибо за ваше время, очень признателен!

Answer 1

В модуле aws_security_group вам нужно вывести идентификатор группы безопасности, добавив следующее в ./modules/services/Security groups // main.tf

output "securitygroup_id" {
  value = aws_security_group.my-webserver.id
}

затем в вашем основном tf-файле прикрепите группу безопасности к вашему экземпляру следующим образом:

resource "aws_network_interface_sg_attachment" "sg_attachment" {
  security_group_id    = module.aws_security_group.securitygroup_id
  network_interface_id = aws_instance.test-ec2deployment.primary_network_interface_id
}