ปัญหาในการแก้ ODE ด้วย DSolve

Question

ฉันกำลังพยายามแก้ ODE ที่ไม่ใช่เชิงเส้นลำดับที่สองด้วยรหัสที่แนบมา หลังจากดูเอกสารสำหรับ DSolve ฉันไม่รู้ว่าฉันทำอะไรผิด เมื่อฉันทำShift+ Enterที่ระดับบนสุด Mathemeatica จะส่งคืนโค้ดที่ฉันป้อนเข้าไป

DSolve[
  -x Derivative[1][y][x] - x Derivative[1][y][x]^3 + 
    y[x]* (1 + Derivative[1][y][x]^2) + 
    y[x]^2 y''[x] + (x^2 - R Sqrt[x^2 + y[x]^2]) y''[x] == 0, 
  y[x], x]

Answer 1

ไม่รู้ว่าจะช่วยได้ไหม แต่ถ้าคุณเปลี่ยนตัวแปรเป็นพิกัดเชิงขั้วเราจะได้รับ ODE ที่DSolveสามารถจัดการได้:

subs = Simplify@NestList[  (* change of variables *)
     D[First@#, x] -> Dt[Last@#]/Dt[r[t] Cos[t]] &,
     y[x] -> r[t] Sin[t], 2]~Join~
   {x -> r[t] Cos[t]};

(* new ode *)
ode = -x*Derivative[1][y][x] - x*Derivative[1][y][x]^3 + 
       y[x]*(1 + Derivative[1][y][x]^2) + 
       y[x]^2*y''[x] + (x^2 - R*Sqrt[x^2 + y[x]^2])*y''[x] /. subs // 
     Together // Numerator // Simplify[#, r[t] > 0] &;
odes = FactorList[ode][[2 ;;, 1]] == 0 // Thread

(*  the process yielded a spurious factor r[t]
  {r[t] == 0, 
   r[t] (r[t] - R) r''[t] + (2 R - r[t]) r'[t]^2 + R r[t]^2 == 0}
*)

dsol = DSolve[Last@odes, r, t]

(*
{{r -> Function[{t}, 
    InverseFunction[-I (ArcTanh[(R - #1)/Sqrt[
           R^2 - 2 R #1 - C[1] #1^2]] - 
          ArcTan[(-R - C[1] #1)/(
           Sqrt[C[1]] Sqrt[R^2 - 2 R #1 - C[1] #1^2])]/Sqrt[C[1]]) &
     ][t + C[2]]]},
 {r -> Function[{t}, 
    InverseFunction[
      I (ArcTanh[(R - #1)/Sqrt[R^2 - 2 R #1 - C[1] #1^2]] - 
          ArcTan[(-R - C[1] #1)/(
           Sqrt[C[1]] Sqrt[R^2 - 2 R #1 - C[1] #1^2])]/Sqrt[C[1]]) &
     ][t + C[2]]]}}
*)

(เพื่อเชื่อมต่อกับความคิดเห็นเกี่ยวกับสมมาตรของฉันการเปลี่ยนแปลงของตัวแปรแสดงให้เห็นว่าระบบไม่แปรผันภายใต้t -> t + t0ซึ่งเป็นการหมุนในพิกัดเชิงขั้ว)