Pas de son - comment puis-je annuler 'sc delete AudioEndpointBuilder'?

Question

Il y a un peu plus d'une semaine, j'ai commis la terrible erreur de courir sc delete AudioEndpointBuilderdans la ligne de commande Windows. Les conséquences ont été vraiment désastreuses.
Je n'ai plus de son dans mon ordinateur! Comment puis-je annuler cette commande apparemment dangereuse?

Une tentative naïve de simplement courir sc create AudioEndpointBuilder n'a pas résolu le problème.

Answer 1

Vous avez quelques options.

1. Vous pouvez télécharger et décompresser le cmdfichier suivant à l'adresse :
   
   

Pour exécuter le fichier, cliquez dessus avec le bouton droit de la souris et choisissez Run as administrator. Le contenu est le suivant:

@Echo off
:: ---------------------------------------------------------------------------------------
:: http://schulze.000webhostapp.com/win10//sc-create-AudiosrvEndpointBuilder.cmd
:: ---------------------------------------------------------------------------------------
:: Unless you substantially alter this code - or merely use small snippets of it - please
:: be sure to leave the following 20 lines intact:
 Echo.
 Echo  DISCLAIMER - Read https://stackoverflow.com/legal/terms-of-service/public#warranties !
 Echo  Credit - https://superuser.com/users/1102737/henke
 Echo  If this cmd file has been helpful to you, the best way to thank me
 Echo  is to upvote both the question and this answer - if you are allowed to.
 Echo     Link to answer - https://superuser.com/questions/1585391#1585392
 Echo  (c) Copyright Henrik D Schulze 2020-09-14 - http://schulze.000webhostapp.com/
 Echo     This answer to 'No sound - how can I undo sc delete AudioEndpointBuilder?'
 Echo  is licensed under [CC BY 4.0](https://creativecommons.org/licenses/by/4.0/)
 Echo.
 Echo  = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
 Echo  =  If you do NOT want to run this file, hit CTRL + C, then Y, then ENTER !  =
 Echo  = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
 Echo.
 Echo  If you WANT to run this file, you need to right-click it and 'Run as administrator'.
 Echo.
:: ---------------------------------------------------------------------------------------
pause

:: Save a backup of the existing registry keys for AudioEndpointBuilder:
%SystemRoot%\System32\reg.exe export^
 HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder^
 %SystemRoot%\OLD!-backupOfAudioEndpointBuilder.reg
:: Delete the existing registry keys for AudioEndpointBuilder:
reg.exe delete HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /f
:: Create the registry keys for AudioEndpointBuilder:
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v Description /d^
 @^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll,-205 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v DisplayName /d^
 @^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll,-204 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ErrorControl /t^
 REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v FailureActions /t^
 REG_BINARY /d "80510100000000000000000003000000140000000100000060ea000001000000c0d401000000000000000000" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v Group /d^
 AudioGroup /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ImagePath /t^
 REG_EXPAND_SZ /d "%%SystemRoot%%\System32\svchost.exe -k LocalSystemNetworkRestricted -p" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ObjectName /d^
 LocalSystem /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v RequiredPrivileges /t^
 REG_MULTI_SZ /d SeChangeNotifyPrivilege /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 ServiceSidType /t REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 Start /t REG_DWORD /d 2 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 Type /t REG_DWORD /d 32 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder\Parameters /v^
 ServiceDll /t REG_EXPAND_SZ /d ^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder\Parameters /v^
 ServiceDllUnloadOnStop /t REG_DWORD /d 1 /f

:: Save a backup of the existing registry keys for Audiosrv:
%SystemRoot%\System32\reg.exe export^
 HKLM\SYSTEM\CurrentControlSet\services\Audiosrv %SystemRoot%\OLD!-backupOfAudiosrv.reg
:: Delete the existing registry keys for Audiosrv:
reg.exe delete HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /f
:: Create the registry keys for Audiosrv:
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v DependOnService /t^
 REG_MULTI_SZ /d "AudioEndpointBuilder\0RpcSs" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v Description /d^
 @^%%SystemRoot^%%\System32\audiosrv.dll,-201 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v DisplayName /d^
 @^%%SystemRoot^%%\System32\audiosrv.dll,-200 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ErrorControl /t^
 REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v FailureActions /t^
 REG_BINARY /d "80510100000000000000000003000000140000000100000060ea000001000000c0d401000100000020bf0200" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v Group /d^
 AudioGroup /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ImagePath /t^
 REG_EXPAND_SZ /d "%%SystemRoot%%\System32\svchost.exe -k LocalServiceNetworkRestricted -p" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ObjectName /d^
 "NT AUTHORITY\LocalService" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v RequiredPrivileges /t^
 REG_MULTI_SZ /d "SeChangeNotifyPrivilege\0SeImpersonatePrivilege\0SeIncreaseWorkingSetPrivilege" /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 ServiceSidType /t REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 Start /t REG_DWORD /d 2 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 Type /t REG_DWORD /d 16 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Parameters /v^
 ServiceDll /t REG_EXPAND_SZ /d ^%%SystemRoot^%%\System32\Audiosrv.dll /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Parameters /v^
 ServiceDllUnloadOnStop /t REG_DWORD /d 1 /f
reg.exe add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Security /v Security /t REG_BINARY /d^
 "01000480c0000000cc00000000000000140000000200ac000600000000001400fd01020001010000000000051200000000001800ff010f0001020000000000052000000020020000000014008d010200010100000000000504000000000014008d010200010100000000000506000000000018008d000200010200000000000f0200000001000000000038008d000200010a00000000000f0300000000040000abace86417c3b0f1abc5110bd73b6dc89d8a33d21867214545351283ff23a71d010100000000000512000000010100000000000512000000" /f

:: Create the services:
sc create AudioEndpointBuilder binPath=^
 ^%%SystemRoot^%%"\system32\svchost.exe -k LocalSystemNetworkRestricted" type= share start= auto
sc create Audiosrv binPath=^
 ^%%SystemRoot^%%"\system32\svchost.exe -k LocalServiceNetworkRestricted" type= share start= auto

:Description
 Echo  Please note!
 Echo  - - - - - -
 Echo  '%0' created the AudioEndpointBuilder Audiosrv services
 Echo  in the registry and in services.msc.
 Echo.
 Echo   = = = = = = = = = = = = = = = = = =
 Echo   =  PLEASE RESTART YOUR COMPUTER!  =   I hope your Audio works now. (It should!)
 Echo   = = = = = = = = = = = = = = = = = =
 Echo.
pause
:: ---------------------------------------------------------------------------------------
 Echo.

Si le script ci-dessus ne restaure pas le son de votre ordinateur, il peut y avoir des problèmes avec le fichier AudioEndpointBuilder.dllet / ou avec audiosrv.dll. Ces deux fichiers sont généralement situés dans C:\Windows\System32\. Ils peuvent être manquants ou avoir la ou les mauvaises versions par rapport à votre version actuelle de Windows 10. Cependant, à moins que vous n'ayez manipulé ces fichiers, il est peu probable que ce soit le problème.
Une autre raison pour laquelle l'exécution du script ne récupère pas votre son peut être des problèmes avec vos pilotes audio. Je considère que c'est aussi une cause improbable. À la Device Manager recherche Sound, video and game controllers. Le moyen le plus simple d'installer les derniers pilotes disponibles consiste peut-être à laisser Windows Update le faire pour vous.

1. Vous pouvez essayer de mettre à niveau vers une version ultérieure de Windows 10. Cela revient en fait à effectuer une nouvelle installation de Windows 10. Sur mon ordinateur portable équipé d'un disque dur, cela a pris environ sept heures. Liens suggérés:
   https://www.askvg.com/windows-10-feature-update-available-for-download-and-upgrade/
   https://support.microsoft.com/en-us/help/4028685/windows -10-get-the-update
   Ou effectuez simplement une recherche en ligne, par exemple pour "Windows 10" "Update & Security" "Update Assistant".

2. Effectuez une nouvelle installation de Windows 10. En faisant cela, vous perdrez tous les logiciels que vous avez installés sur votre ordinateur, donc cela ne doit être considéré qu'en dernier recours.