"PlotLabel" per i grafici in una "Table"

Question

Ho un Tablecontenente due trame, fornite da

Table[
 Plot[{Re[f[n]] /. j -> 3, Im[f[n]] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, PlotRange -> All, PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel -> f[n]], 
{f, {Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] & , 
   (-1 + E^(2*I*Pi*#1))/(j*(-1 + E^((2*I*Pi*#1)/j))) & }}
]

Come puoi vedere, Mathematica ha riscritto il primo PlotLabel(cioè Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] &) in un'espressione che considera più utile o naturale. Non voglio che lo faccia. Voglio PlotLabelche la trama sia simile a questa:

cioè, come se fosse stato scritto PlotLabel -> "expr". Ma l'altra etichetta è già come la voglio io.

Ho sperimentato l'utilizzo StringFormma non aiuta. Come faccio a fare questo? O non è possibile?

Answer 1

Table[Plot[{Re[ReleaseHold@f] /. j -> 3,  Im[ReleaseHold@f] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, 
  PlotRange -> All, ImageSize -> 350, 
  PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel ->  f], 
{f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
   HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]

Puoi sostituire HoldForme ReleaseHoldcon Defere First, rispettivamente, per ottenere lo stesso risultato.

Come suggerito da Bob Hanlon nei commenti, nelle versioni 12.0+ puoi usare ReImPlotcome segue:

 Table[ReImPlot[ReleaseHold[f] /. j -> 3, {n, 0, 15}, 
    GridLines -> Automatic, PlotRange -> All, ImageSize -> 350, 
    PlotLegends -> "ReIm", 
    ReImLabels -> {"Real", "Imaginary"}, 
    ReImStyle -> {ColorData[97][1], {ColorData[97][2], Dashing[{}]}},
    PlotLabel -> f], 
  {f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
      HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]