Mathematica를 사용하여 성공적으로 해결 된 3D 제약 적분의 수정에 대한 추측 공식 확인

Question

특정 3 차원 제약 적분의 솔루션이 형식을 취한다는 다소 간접적이며 완전히 결정적이지 않은 증거를 얻었습니다.

1/576 (8 - 6 Sqrt[2] + 15 Sqrt[2] \[Pi] - 48 Sqrt[2] ArcTan[Sqrt[2]])

$\approx 0.00227243$. 여기서 제 질문은이 추측이 공식적으로 검증 될 수 있는지 여부입니다 (물론 Mathematica를 사용하여).

문제의 문제는 3 차원 통합을 성공적으로 수정하고 사용자 JimB가 답변에서 매우 인상적으로 해결 한 것입니다.

29902415923/497664 - 50274109/(512 Sqrt[2]) - (3072529845 π)/(32768 Sqrt[2]) +(1024176615 ArcCos[1/3])/(4096 Sqrt[2])

$\approx 0.00365826$

에 Original3Dproblem .

우리는 (의 표기 다음과 같은 우리의 후보 솔루션을 확인하고자하는 특정 통합 문제 Original3Dproblem는 )입니다

Integrate[Boole[Subscript[λ, 1] > Subscript[λ, 2] && Subscript[λ, 2] > Subscript[λ, 3] &&Subscript[λ, 3] > 1 - Subscript[λ, 1] - Subscript[λ, 2] - Subscript[λ, 3] && Subscript[λ, 1] -Subscript[λ, 3] < 2 Sqrt[Subscript[λ, 2] (1 - Subscript[λ, 1] - Subscript[λ, 2] - Subscript[λ,3])]], {Subscript[λ, 3], 0, 1}, {Subscript[λ, 2], 0, 1}, {Subscript[λ, 1], 0, 1}]  .

(수정되지 않은) 질문 Original3Dproblem 도 제한 형식으로 제시되었지만 N. Tessore가 제안한 변환을 사용하는 제한되지 않은 형식으로 변환되었습니다.

change = {Subscript[λ, 1] -> x/(1 + 2 x), Subscript[λ, 2] -> y/(1 + y) (1 + x)/(1 + 2 x),Subscript[λ, 3] -> z 1/(1 + y) (1 + x)/(1 + 2 x)},

현재 (수정 된) 질문에 대해 명확하게 적용 가능하며 변형 된 제약없는 문제가 발생합니다.

Integrate[(1 + x)^2/((1 + 2 x)^4 (1 + y)^3), {z, 1/2, 1}, {y, z, 2 + 2Sqrt[1 - z] - z}, {x, y, 2 Sqrt[-((-y - 2 y^2 - y^3 + y z + 2 y^2 z + y^3 z)/(-1 + y + z)^4)] + ( 4 y + z - 3 y z - z^2)/(-1 + y + z)^2}],

또한 처음에 주어진 공식을 추측 적으로 산출합니다.

이 문제를 (아직) 직접 해결할 수는 없었지만 Mathematica를 사용하여 볼록 집합의 경계 영역에 대한 관련 2D 통합을 해결하여 부등식 제약 조건을 수정했습니다.

 Subscript[λ, 1] -Subscript[λ, 3] < 2 Sqrt[Subscript[λ, 2] (1 - Subscript[λ, 1] - Subscript[λ, 2] - Subscript[λ,3])]

평등 제약에

 Subscript[λ, 1] -Subscript[λ, 3] == 2 Sqrt[Subscript[λ, 2] (1 - Subscript[λ, 1] - Subscript[λ, 2] - Subscript[λ,3])].

이 2D 문제에 대한 해결책은

1/96 (8 - 6 Sqrt[2] + 15 Sqrt[2] \[Pi] - 48 Sqrt[2] ArcTan[Sqrt[2]])

$\approx 0.013634585$.

추측 된 공식을 얻는 열쇠

1/576 (8 - 6 Sqrt[2] + 15 Sqrt[2] \[Pi] - 48 Sqrt[2] ArcTan[Sqrt[2]])

여기서 검증을 구하는 것은 3D 문제에 대한 해의 수치 적분 추정치 (0.002272430980282073)에 대한 0.013634585916219의 (면적 / 부피) 비율이 6.000000015193957이며 정확한 값 6을 가리키는 것입니다.

면적 / 체적 비율이 실제로 6이면 해당 세트가 알려진 범주에 속할 경우 해당 세트의 특정 특성을 식별하는 데 유용한 단서가 될 수 있습니다. (단순한 예로서, 반경의 3 차원 공$\frac{1}{2}$ 그런 비율이 있습니다.)

여기서 추구하는 수정은 Original3Dproblem 에서 (Hilbert-Schmidt [eq. (15.35)] GeometryQuantumStates ) 적분을 대체하는 것입니다.

9081072000 (Subscript[λ, 1] - Subscript[λ, 2])^2 (Subscript[λ, 1] - Subscript[λ, 3])^2 (Subscript[λ, 2] - Subscript[λ, 3])^2 (-1 + 2 Subscript[λ, 1] + Subscript[λ, 2] + Subscript[λ, 3])^2 (-1 + Subscript[λ, 1] + 2 Subscript[λ, 2] + Subscript[λ, 3])^2 (-1 + Subscript[λ, 1] + Subscript[λ, 2] + 2 Subscript[λ, 3])^2 

간단히 1로.

이 수정의 동기는 문제를 (Hermitian, non-negative-definite)의 4 가지 순서 고유 값의 문제로 간주하기보다는 $4 \times 4$, trace 1) 이러한 행렬에 대한 15 차원 설정의 "2 큐 비트 밀도 행렬", 이제 3 차원 볼록 집합에 중점을 둡니다. $(\lambda_1, \lambda_2, \lambda_3, 1-\lambda_1-\lambda_2-\lambda_3)$ "절대적으로 분리 가능한 2- 큐 비트 밀도 행렬의 정렬 된 스펙트럼".

우리는이 문제에 관심이 있습니다. 그 해법이 표시된 볼록 세트의 유클리드 부피를 산출 할 수 있기 때문에 JohnEllipsoidProblem이이 를 둘러싸고 표시 하는 최소 및 최대 부피의 "John 타원체"를 찾을 수 있습니다.

Answer 1

첫 번째 질문 $\frac{1}{2} \cos ^{-1}\left(\frac{1}{3}\right)-\frac{\pi }{8}$ 다음과 같다 $\csc ^{-1}\left(\sqrt{6 \left(\sqrt{2}+2\right)}\right)$ 그래서 방정식은 다음과 같이 단순화 될 수 있습니다.

1/288 (4 - 3 Sqrt[2] - 6 Sqrt[2] ArcCsc[3] + 12 Sqrt[2] ArcCsc[Sqrt[6 (2 + Sqrt[2])]]) /. 
  ArcCsc[Sqrt[6 (2 + Sqrt[2])]] -> -(π/8) + 1/2 ArcCos[1/3] /. 
  ArcCsc[3] -> π/2 - ArcCos[1/3] // Expand // Together

(*  1/576 (8 - 6 Sqrt[2] - 9 Sqrt[2] π + 24 Sqrt[2] ArcCos[1/3]) *)

이전 질문에서와 같이 용어 ArcCos[1/3}가 포함 되기를 원하는 것 같았습니다 .

다음 부분은 Mathematica 를 사용 하여 결과를 얻는 것입니다.

Boole공식 1 의 일부를 취하면 5 개의 통합이 수행 될 수 있습니다.

Reduce[Subscript[λ, 1] > Subscript[λ, 2] && Subscript[λ, 2] > Subscript[λ, 3] && 
  Subscript[λ, 3] > 1 - Subscript[λ, 1] - Subscript[λ, 2] - Subscript[λ, 3] && 
  Subscript[λ, 1] - Subscript[λ, 3] < 2 Sqrt[Subscript[λ, 2] (1 - Subscript[λ, 1] - Subscript[λ, 2] - Subscript[λ, 3])]]

그리고 그 결과에 대한 약간의 조작 후에 하나는 통합 할 5 개의 영역으로 끝납니다.

다음은 개별 통합을 수행합니다.

통합 1

i1 = Integrate[1, {λ1, 1/4, 1/3}, {λ2, 1/3 (1 - λ1), λ1}, {λ3, 1/2 (1 - λ1 - λ2), λ2}]
(* 1/3888 *)

통합 2 :

i2 = Integrate[1, {λ1, 1/3, 1/8 (2 + Sqrt[2])}, 
  {λ2, 1/3 (1 - λ1), 1/9 (2 - λ1) + 2/9 Sqrt[1 - λ1 - 2 λ1^2]}, 
  {λ3, 1/2 (1 - λ1 - λ2), λ2}]
(* (998-447 Sqrt[2]+972 Sqrt[2] ArcSin[1/54 (20-23 Sqrt[2])])/62208 *)

세 번째 통합은 몇 가지 복잡한 제곱근 함수를 생성하고 @CarlWoll 의 denestSqrt 함수가 사용됩니다.

denestSqrt[e_, domain_, x_] := Replace[y /. Solve[Simplify[Reduce[Reduce[y == e && domain, x], y, Reals], domain], y], {{r_} :> r, _ -> e}]

i3a = Integrate[1, {λ2, 1/9 (2 - λ1) + 2/9 Sqrt[1 - λ1 - 2 λ1^2], λ1}, 
  {λ3, 1/2 (1 - λ1 - λ2), λ1 - 2 λ2 + 2 Sqrt[λ2 - 2 λ1 λ2]}, 
    Assumptions -> {1/3 < λ1 <= 1/8 (2 + Sqrt[2])}] // Expand;
i3a = i3a /. Sqrt[1 - 2 λ1] Sqrt[2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2]] -> 
  denestSqrt[Sqrt[(1 - 2 λ1) (2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2])], 1/3 < λ1 <= 1/8 (2 + Sqrt[2]), λ1] /.
  Sqrt[1 - 2 λ1] λ1 Sqrt[2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2]] -> 
  denestSqrt[λ1 Sqrt[(1 - 2 λ1) (2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2])], 
  1/3 < λ1 <= 1/8 (2 + Sqrt[2]), λ1] /.
  Sqrt[1 - 2 λ1] Sqrt[1 - λ1 - 2 λ1^2] Sqrt[2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2]] -> 
  denestSqrt[Sqrt[(1 - 2 λ1) (1 - λ1 - 2 λ1^2) (2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2])], 
  1/3 < λ1 <= 1/8 (2 + Sqrt[2]), λ1] // Expand;
i3a1 = Integrate[-(1/81), {λ1, 1/3, 1/8 (2 + Sqrt[2])}];
i3a2 = Integrate[-((50 λ1)/81), {λ1, 1/3, 1/8 (2 + Sqrt[2])}];
i3a3 = Integrate[4/3 Sqrt[1 - 2 λ1] λ1^(3/2), {λ1, 1/3, 1/8 (2 + Sqrt[2])}] // ToRadicals;
i3a4 = Integrate[(77 λ1^2)/81, {λ1, 1/3, 1/8 (2 + Sqrt[2])}];
i3a5 = Integrate[-(1/81) Sqrt[1 - λ1 - 2 λ1^2], {λ1, 1/3, 1/8 (2 + Sqrt[2])}];
i3a6 = Integrate[-(10/81) λ1 Sqrt[1 - λ1 - 2 λ1^2], {λ1, 1/3, 1/8 (2 + Sqrt[2])}];
i3 = i3a1 + i3a2 + i3a3 + i3a4 + i3a5 + i3a6 // Expand
(* -(329/31104)+133/(31104 Sqrt[2])-ArcSin[1/54 (20-23 Sqrt[2])]/(96 Sqrt[2])+ArcSin[1/2 Sqrt[1/3 (2-Sqrt[2])]]/(24 Sqrt[2]) *)

통합 4

i4 = Integrate[1, {λ1, 1/8 (2 + Sqrt[2]), 1/2}, 
  {λ2, 1/3 (1 - λ1), 1/9 (2 - λ1) + 2/9 Sqrt[1 - λ1 - 2 λ1^2]}, 
  {λ3, 1/2 (1 - λ1 - λ2), λ2}]
(* (-2+149 Sqrt[2]-324 Sqrt[2] ArcCos[1/6 (4+Sqrt[2])])/20736 *)

통합 5 :

i5a = Integrate[1, {λ2, 1/9 (2 - λ1) + 2/9 Sqrt[1 - λ1 - 2 λ1^2],
  1/9 (5 - 7 λ1) + 4/9 Sqrt[1 - λ1 - 2 λ1^2]}, 
  {λ3, 1/2 (1 - λ1 - λ2), λ1 - 2 λ2 + 2 Sqrt[λ2 - 2 λ1 λ2]}, 
  Assumptions -> {1/8 (2 + Sqrt[2]) < λ1 < 1/2}] // Expand;

i5a = i5a /. Sqrt[1 - 2 λ1] Sqrt[2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2]] ->
  denestSqrt[Sqrt[(1 - 2 λ1) (2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2])], 1/8 (2 + Sqrt[2]) < λ1 < 1/2, λ1] /.
  Sqrt[1 - 2 λ1] λ1 Sqrt[2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2]] -> 
  λ1 denestSqrt[Sqrt[(1 - 2 λ1) (2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2])], 1/8 (2 + Sqrt[2]) < λ1 < 1/2, λ1] /.
  Sqrt[1 - 2 λ1] Sqrt[1 - λ1 - 2 λ1^2] Sqrt[2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2]] -> 
  denestSqrt[Sqrt[(1 - 2 λ1) (1 - λ1 - 2 λ1^2) (2 - λ1 + 2 Sqrt[1 - λ1 - 2 λ1^2])], 1/8 (2 + Sqrt[2]) < λ1 < 1/2, λ1] /.
  Sqrt[1 - 2 λ1] Sqrt[5 - 7 λ1 + 4 Sqrt[1 - λ1 - 2 λ1^2]] -> 
  denestSqrt[Sqrt[(1 - 2 λ1) (5 - 7 λ1 + 4 Sqrt[1 - λ1 - 2 λ1^2])], 1/8 (2 + Sqrt[2]) < λ1 < 1/2, λ1] /.
  Sqrt[1 - 2 λ1] λ1 Sqrt[5 - 7 λ1 + 4 Sqrt[1 - λ1 - 2 λ1^2]] -> 
  λ1 denestSqrt[Sqrt[(1 - 2 λ1) (5 - 7 λ1 + 4 Sqrt[1 - λ1 - 2 λ1^2])], 1/8 (2 + Sqrt[2]) < λ1 < 1/2, λ1] /.
  Sqrt[1 - 2 λ1] Sqrt[1 - λ1 - 2 λ1^2] Sqrt[5 - 7 λ1 + 4 Sqrt[1 - λ1 - 2 λ1^2]] -> 
    denestSqrt[Sqrt[(1 - 2 λ1) (1 - λ1 - 2 λ1^2) (5 - 7 λ1 + 4 Sqrt[1 - λ1 - 2 λ1^2])], 1/8 (2 + Sqrt[2]) < λ1 < 1/2, λ1] // Expand
(* 7/324+(2 λ1)/81-(11 λ1^2)/81+1/27 Sqrt[1-λ1-2 λ1^2]-2/27 λ1 Sqrt[1-λ1-2 λ1^2] *)
i5 = Integrate[i5a, {λ1, 1/8 (2 + Sqrt[2]), 1/2}]
(* (514-781 Sqrt[2]+972 Sqrt[2] ArcCos[1/6 (4+Sqrt[2])])/62208 *)

함께 추가 :

result = i1 + i2 + i3 + i4 + i5 // FullSimplify
1/288 (4 - 3 Sqrt[2] + 6 Sqrt[2] ArcCsc[Sqrt[6 (2 + Sqrt[2])]] + 3 Sqrt[2] ArcSin[1/54 (20 - 23 Sqrt[2])])

이것은 더 단순화 될 수 있습니다

result /. ArcSin[1/54 (20 - 23 Sqrt[2])] -> -((5 \[Pi])/4) + 3 ArcCos[1/3] /. 
   ArcCsc[Sqrt[6 (2 + Sqrt[2])]] -> -(\[Pi]/8) + 1/2 ArcCos[1/3] // Expand // Together
(* 1/576 (8 - 6 Sqrt[2] - 9 Sqrt[2] \[Pi] + 24 Sqrt[2] ArcCos[1/3]) *)