Domanda sulla ricerca dell'area

Question

Ecco un collegamento alla mia domanda precedente Domanda sul tracciamento di una curva e di linee tangenti

Voglio sapere come si può trovare l'area tra la curva e la tangente tra il punto Fun1 e Fun2. Questo è quello che ho fatto ma non sono sicuro che sia corretto o meno. Devo usare l'integrazione a tratti?

    Clear[f, x, g]
    f[x_] = x^3
    g = f[1.2] + f'[1.2] (x - 1.2)
    Plot[{f[x], g}, {x, -5, 5}, PlotRange -> 20]
    NIntegrate[f[x], {x, -2.4, 1.4}]
    NIntegrate[f[x], {x, -2.4, 4.8}]

Voglio anche sapere come posso far funzionare la funzione Manipola per spostare il punto Fun1 a 15 posizioni nell'intervallo [-5,0). Voglio anche imparare come posso usare la funzione Manipola per aggiornare il disegno ogni volta che i punti si spostano (il disegno mostra le tangenti i punti di intersezione)

    Manipulate[
    Plot[{f[x],l[x]}, {t, -x, x}, Filling -> Axis, 
    PlotRange -> {{-5, 10}, {-5, 10}}, N[Erf[x]]], {1.3, 0.5}]], {x,
    0.0001, 3}]

Answer 1

ClearAll[f, t]
f[x_] := x^3
t[x0_][x_] := f[x0] + f'[x0] (x - x0)


With[{x0 = 2}, Plot[{f@x, t[x0]@x, ConditionalExpression[t[x0]@x, x <= x0 ]}, {x, -5, 5},
     PlotRange -> {{-5, 5}, {-80, 80}}, 
     Filling -> {1 -> {{3}, {None, LightBlue}}},
     PlotStyle -> {Automatic, Automatic, None},
     ImageSize -> Large,
     MeshFunctions -> {# &, f@# - t[x0]@# &},  Mesh -> {{x0}, {0}}, 
     MeshStyle -> Directive[PointSize@Large, Red], 
     DisplayFunction -> (Show[#, 
      Epilog -> First@Cases[Normal@#, 
         p_Polygon :> Text[Style[ Column[{"area:", Area[p]}, Alignment -> Center],
             14], RegionCentroid[p]], All]] &)]] 

Manipulate[Plot[{f@x, t[x0]@x, ConditionalExpression[t[x0]@x, -8 < x <= x0 ]}, 
  {x, -8, 5}, 
  PlotRange -> {{-8, 8}, {-220, 70}}, 
  Filling -> {1 -> {{3}, {None, LightBlue}}},
  PlotStyle -> {Automatic, Automatic, None},
  ImageSize -> Large,
  MeshFunctions -> {# &, f@# - t[x0]@# &},  
  Mesh -> {{x0}, {0}}, 
  MeshStyle -> Directive[PointSize[Large], Red], 
  DisplayFunction -> (Show[# , 
      Epilog -> {Text[Style[Round[#, .1], 16, Black], #, {-1, 3/2}] & /@ 
         Cases[Normal@#, Point[x_] :> x, All][[;; 2]]},  
      PlotLabel -> Style[PromptForm["shaded area", 
         First @ Cases[Normal@#, p_Polygon :> Area[p], All]], 20]] &)],
 {{x0, 2}, 0, 3, .1}]