z 평면에서 w 평면으로 등각 매핑을 그리는 방법

Question

저는 Mathematica의 완전 초보자입니다. 아무것도 몰라. 지도의 등각 특성을 보여주기 위해 다이어그램을 그려야합니다.$w=e^z$.

윤곽을 그려야합니다 $z$-비행기; 예 : 수평선, 수직선, 45도 선 및 단위 원. 그런 다음 매핑 된 곡선을 가져와야합니다.$w$-어디 비행기 $u$ 과 $v$ 의 기능입니다 $x$ 과 $y$.

어떻게 해야할지 모르겠어요? 제발 도와주세요.

Answer 1

댓글에 답장하십시오.

MeshShading영역을 채우는 데 사용 합니다.

expr1 = {x, y};
expr2 = With[{z = x + I*y}, E^z // ReIm // ComplexExpand];
ParametricPlot[#, {x, -4, 4}, {y, -4, 4}, 
    MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
    Mesh -> {{1}, {1}, {0}, {1}}, 
    MeshShading -> {{{{Red, None}, {None, None}}, {{Red, None}, {None,
          None}}}, {{{None, None}, {None, None}}, {{None, 
         None}, {None, None}}}}, 
    MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
       Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
       Opacity[1]}}, Axes -> False, PlotRange -> 4, 
    BoundaryStyle -> None, 
    LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
    PlotStyle -> None] & /@ {expr1, expr2} // GraphicsRow

단순화

expr1 = {x, y};
expr2 = With[{z = x + I*y}, E^z // ReIm // ComplexExpand];
ParametricPlot[#, {x, -4, 4}, {y, -4, 4}, 
    MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
    Mesh -> {{1}, {1}, {0}, {1}}, 
    MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
       Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
       Opacity[1]}}, Axes -> False, PlotRange -> 4, 
    BoundaryStyle -> None, 
    LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
    PlotStyle -> None] & /@ {expr1, expr2} // GraphicsRow

실물

expr = With[{z = x + I*y}, E^z // ReIm // ComplexExpand]
xy = ParametricPlot[{x, y}, {x, -2, 2}, {y, -2, 2}, 
   MeshFunctions -> {#1 &, #2 &, #2 - #1 &, Sqrt[#1^2 + #2^2] &}, 
   Mesh -> {{1}, {1}, {0}, {1}}, 
   MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
      Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
      Opacity[1]}}, PlotPoints -> 50, FrameLabel -> {x, y}, 
   PlotStyle -> None];
uv = ParametricPlot[expr, {x, -4, 4}, {y, -4, 4}, 
   MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
   Mesh -> {{1}, {1}, {0}, {1}}, 
   MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
      Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
      Opacity[1]}}, Axes -> False, PlotRange -> 8, 
   BoundaryStyle -> None, FrameLabel -> {u, v}, 
   LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
   PlotStyle -> None];
GraphicsRow[{xy, uv}]