Geração de malha 1D para solução PDE
Estou tentando resolver um sistema de dois PDE que dependem do tempo e da distância (H [x, t] e P [x, t]). Estou resolvendo o problema usando o método das linhas, mas quero gerar eu mesmo a malha e introduzi-la no NDsolve. A malha que desejo gerar é a seguinte
Preciso de uma malha como esta porque os valores de uma das funções (P [x, t]) mudam com o tempo apenas muito perto de x = 0, enquanto H [x, t] muda em toda a região 0 <x < xmax. Abaixo está um exemplo do código que estou usando
(* Constants *)
f = 38.94; logL = -2;
Ls = 10^logL; a = 0.5;
C1 = 1*^-5; dH = 1*^-6;
Ea = 0.1;
tmax = 40; (* Time in seconds *)
xmax = 10 Sqrt[dH] Sqrt[tmax]; (* Maximum distance to simulate. cm *)
(* PDE system *)
eqsH = {D[H[x, t], t] - dH D[H[x, t], x, x] == NeumannValue[Ls Exp[a f Ea ] P[x, t] - Ls Exp[-a f Ea ] H[x, t],
x == 0], H[x, 0] == 1};
eqsP = {D[P[x, t], t] == NeumannValue[-Ls Exp[a f Ea ] P[x, t] + Ls Exp[-a f Ea ] H[x, t],
x == 0], P[x, 0] == 1};
(*Solution of the differential equations*)
prec = 7;
msf = 0.001;
sol = NDSolve[{eqsH, eqsP}, {H, P}, {x, 0, xmax}, {t, 0, tmax},
AccuracyGoal -> prec, PrecisionGoal -> prec,
Method -> {"MethodOfLines",
"SpatialDiscretization" -> {"FiniteElement"}}] // First //
Quiet;
Posso obter ajuda sobre como criar a malha e apresentá-la no NDSolve? desde já, obrigado !
Respostas
Aqui está uma abordagem alternativa usando uma malha graduada.
Defina algumas funções auxiliares para uma malha graduada
Aqui estão algumas funções que usei para criar malhas anisotrópicas 1d a 3D. Nem todas as funções são usadas.
(*Import required FEM package*)
Needs["NDSolve`FEM`"];
(* Define Some Helper Functions For Structured Meshes*)
pointsToMesh[data_] :=
MeshRegion[Transpose[{data}],
Line@Table[{i, i + 1}, {i, Length[data] - 1}]];
unitMeshGrowth[n_, r_] :=
Table[(r^(j/(-1 + n)) - 1.)/(r - 1.), {j, 0, n - 1}]
meshGrowth[x0_, xf_, n_, r_] := (xf - x0) unitMeshGrowth[n, r] + x0
firstElmHeight[x0_, xf_, n_, r_] :=
Abs@First@Differences@meshGrowth[x0, xf, n, r]
lastElmHeight[x0_, xf_, n_, r_] :=
Abs@Last@Differences@meshGrowth[x0, xf, n, r]
findGrowthRate[x0_, xf_, n_, fElm_] :=
Quiet@Abs@
FindRoot[firstElmHeight[x0, xf, n, r] - fElm, {r, 1.0001, 100000},
Method -> "Brent"][[1, 2]]
meshGrowthByElm[x0_, xf_, n_, fElm_] :=
N@Sort@Chop@meshGrowth[x0, xf, n, findGrowthRate[x0, xf, n, fElm]]
meshGrowthByElm0[len_, n_, fElm_] := meshGrowthByElm[0, len, n, fElm]
flipSegment[l_] := (#1 - #2) & @@ {First[#], #} &@Reverse[l];
leftSegmentGrowth[len_, n_, fElm_] := meshGrowthByElm0[len, n, fElm]
rightSegmentGrowth[len_, n_, fElm_] := Module[{seg},
seg = leftSegmentGrowth[len, n, fElm];
flipSegment[seg]
]
reflectRight[pts_] := With[{rt = ReflectionTransform[{1}, {Last@pts}]},
Union[pts, Flatten[rt /@ Partition[pts, 1]]]]
reflectLeft[pts_] :=
With[{rt = ReflectionTransform[{-1}, {First@pts}]},
Union[pts, Flatten[rt /@ Partition[pts, 1]]]]
extendMesh[mesh_, newmesh_] := Union[mesh, Max@mesh + newmesh]
Crie um segmento de malha horizontal graduado
O seguinte criará uma região de malha horizontal de 100 elementos onde a largura inicial do elemento é 1/10000 do comprimento do domínio.
(*Create a graded horizontal mesh segment*)
(*Initial element width is 1/10000 the domain length*)
seg = leftSegmentGrowth[xmax, 100, xmax/10000];
Print["Horizontal segment"]
rh = pointsToMesh@seg
(*Convert mesh region to element mesh*)
(*Extract Coords from horizontal region*)
crd = MeshCoordinates[rh];
(*Create element mesh*)
mesh = ToElementMesh[crd];
Print["ListPlot of exponential growth of element size"]
ListPlot[Transpose@mesh["Coordinates"]]
Pode-se ver o crescimento exponencial do tamanho do elemento conforme o número do elemento aumenta.
Converta a região da malha em uma malha de elemento e resolva o PDE
Geralmente, converto o MeshRegionem um 'ElementMesh' para poder aplicar marcadores de elemento e ponto, se necessário.
(*Solve PDE on graded mesh*)
{Hfun, Pfun} =
NDSolveValue[{eqsH, eqsP}, {H, P}, x ∈ mesh, {t, 0, tmax},
Method -> {"MethodOfLines",
"SpatialDiscretization" -> {"FiniteElement"}}];
(*Animate Hfun solution*)
imgs = Plot[Hfun[x, #], x ∈ mesh,
PlotRange -> {0.9999999, 1.0018}] & /@ Subdivide[0, tmax, 120];
Print["Animation of Hfun solution"]
ListAnimate@imgs
Apêndice: Exemplos de malha anisotrópica
Como aludi no comentário abaixo, a lista com marcadores abaixo mostra vários exemplos em que usei a malha quadrada anisotrópica para capturar interfaces nítidas que, de outra forma, seriam muito caras em termos computacionais. O código é funcional, mas não ideal e algumas das funções foram modificadas ao longo do tempo. Use por sua conta e risco
- 2D-Estacionário
- Mathematica vs. MATLAB: por que estou obtendo resultados diferentes para PDE com condição de contorno não constante?
- Melhorando a convergência da solução mesh e NDSolve
- 2D-Transiente
- Controlando o tamanho do intervalo de tempo dinâmico em NDSolveValue
- Como modelar a difusão através de uma membrana?
- Transporte de massa FEM usando malha quadrada
- NDSolve com sistema de equação com funções desconhecidas definidas em diferentes domínios
- 3D-Malha
- Criar malha graduada
- 3D-estacionário
- Como melhorar a solução FEM com NDSolve?
- Potencial de vetor FEM 3D
Se você tiver acesso a outras ferramentas, como o COMSOL, que possuem funcionalidade de camada limite, você pode importar malhas através da função de recurso FEMAddOns . Não funcionará para malhas 3D que requerem tipos de elementos adicionais como prismas e pirâmides que atualmente não são suportados no FEM do Mathematica .
Que tal isso?
lst1 = Partition[
Join[Table[0.01*i, {i, 0, 5}], Table[0.1*i, {i, 0, 15}]], 1];
lst2 = Table[{i, i + 1}, {i, 1, Length[lst1] - 1}];
<< NDSolve`FEM`
mesh2 = ToElementMesh["Coordinates" -> lst1,
"MeshElements" -> {LineElement[lst2]}]
(* ElementMesh[{{0., 1.5}}, {LineElement["<" 21 ">"]}] *)
Vamos visualizar isso:
mesh2["Wireframe"["MeshElementIDStyle" -> Red]]
As figuras vermelhas indicam os elementos da malha. O lugar onde eles se sobrepõem é na verdade aquele onde a malha é 10 vezes mais densa (veja a imagem ampliada abaixo):
Diverta-se!