Bir polinomun yalnızca çift köke sahip olması için kriterleri nasıl bulabilirim?

Question

İşlevin yardım belgesinde, SolveAlwaysbir polinomun üçlü köke sahip olması koşulunu gördüm.

(*Find a condition for a cubic polynomial to have a triple root:*)
f[x_] := x^3 + a x^2 + b x + c;
SolveAlways[Implies[f[x] == 0 && f[y] == 0, x == y], {x, y}]

Şimdi, bir polinomun sadece bir çift köke sahip olduğu bir koşulu bulmak için bu örneği taklit etmek istiyorum (ikinci dereceden daha yüksek birden fazla kök yoktur).

A = {{1, 2, -3}, {-1, 4, -3}, {1, a, 5}};
f[λ_] := CharacteristicPolynomial[A, λ]
Reduce[Exists[{x, y}, Implies[f[x] == 0 && f[y] == 0, x == y]], {a}]
Solve[(f[x] /. a -> -2) == 0, x]

SolveAlways[Implies[(f[x] == f'[x] == 0), f''[x] != 0], x]

Ancak yukarıdaki kodun çıktısı bir değerlendirme koşulu değildir. Bu sorunu çözmek için ne yapabilirim?

Answer 1

Ayrımcının yok olmasını ve türevin ayrımcısının yok olmamasını istiyorsunuz.

mat = {{1, 2, -3}, {-1, 4, -3}, {1, a, 5}};
cpoly = CharacteristicPolynomial[mat, x];
disc1 = Discriminant[cpoly, x]
disc2 = Discriminant[D[cpoly, x], x]

(* Out[616]= -288 - 720 a - 504 a^2 - 108 a^3

Out[617]= -4 (2 + 9 a) *)

Şimdi bunları çözün.

Reduce[disc1 == 0 && disc2 != 0]

(* Out[618]= a == -2 || a == -(2/3) *)

Answer 2

Çokluk 2'nin kökü tanımından yararlanılarak elde edilen

A = {{1, 2, -3},{-1, 4, -3},{1, a, 5}};f[\[Lambda]_]:= CharacteristicPolynomial[A,\[Lambda]]
Reduce[Exists[x, f[x] == 0 && f'[x] == 0 && f''[x] != 0], a, Reals]
(*a == -2 || a == -(2/3)*)

Bu yaklaşım sadece polinomlar için işe yaramaz.

Answer 3

Bu nedir ayırt edici kullanılabileceği düşünüldü:

Reduce[Discriminant[CharacteristicPolynomial[{{1, 2, -3},
                                              {-1, 4, -3},
                                              {1, a, 5}}, x], x] == 0, a]
   a == -2 || a == -2/3

Kontrol:

With[{a = -2/3}, Eigenvalues[{{1, 2, -3}, {-1, 4, -3}, {1, a, 5}}]]
   {4, 4, 2}

With[{a = -2}, Eigenvalues[{{1, 2, -3}, {-1, 4, -3}, {1, a, 5}}]]
   {6, 2, 2}