Como contar o enésimo primo no prólogo

Question

Eu sou muito novo no prólogo e estou tentando escrever um predicado que forneça o valor do n-ésimo número primo e parece nth_prime(N, Prime) . Já fiz a função que conta se o número é primo ou não

div(X, Y):- 0 is X mod Y.
div(X, Y):- X>Y+1, Y1 is Y+1, div(X, Y1).

prime(2):- true.
prime(X):- X<2, false.
prime(X):- not(div(X, 2)).

Não entendo qual é o meu próximo passo e como devo contar quais primos pertencem a N.

Answer 1

Seu código é um pouco incomum para prólogo, mas (com exceção de prime(1)) ele funciona.

Aqui está uma solução para seu predicado:

nextprime(N,N):- 
    prime(N),
    !.
nextprime(P, Prime):-
    PP is P+1,
    nextprime(PP,Prime).

nthprime(1, 2).
nthprime(N, Prime):-
    N>1,
    NN is N-1,
    nthprime(NN, PrevPrime),
    PP is PrevPrime+1,
    nextprime(PP, Prime).

?- nthprime(1,P).
P = 2 ;
false.

?- nthprime(2,P).
P = 3 ;
false.

?- nthprime(3,P).
P = 5 ;
false.

Funciona da seguinte forma: Sabe-se que o primeiro número primo é 2 ( nthprime(1, 2).). Para cada outro número Nmaior que 1, obtenha o número primo anterior ( nthprime(NN, PrevPrime)), some 1 até chegar a um número primo. A parte somar 1 é feita por meio de um predicado de ajuda nextprime/2: para um determinado número, Pele verificará se esse número é primo. Se sim, ele retorna este número, caso contrário, ele chamará a si mesmo para o próximo número superior ( nextprime(PP,Prime)) e encaminha a saída. O estrondo !é chamado de corte que corta os outros ramos de escolha. Portanto, se você atingir um primo uma vez, não poderá voltar e tentar o outro caminho.

Para testar você pode pedir ?- nthprime(N,P).um dado N. Ou, para verificar várias respostas de uma vez, vamos apresentar um predicado auxiliar nthprimeList/2que chama nthprime/2todos os itens da primeira lista e coloca a "saída" em uma lista:

nthprimeList([],[]).
nthprimeList([N|TN],[P|TP]):-
    nthprime(N,P),
    nthprimeList(TN,TP).

?- nthprimeList([1,2,3,4,5,6,7,8,9],[P1,P2,P3,P4,P5,P6,P7,P8,P9]).
P1 = 2,
P2 = 3,
P3 = 5,
P4 = 7,
P5 = 11,
P6 = 13,
P7 = 17,
P8 = 19,
P9 = 23;
false.

Answer 2

Usando suas definições, definimos o seguinte para contar e testar todos os números de 2 para cima, um após o outro:

nth_prime(N, Prime):-
  nth_prime(N, Prime, 1, 2).  % 2 is the candidate for 1st prime

nth_prime(N, P, I, Q):-   % Q is I-th prime candidate
  prime(Q) 
  -> ( I = N, P = Q
     ; I1 is I+1, Q1 is Q+1, nth_prime(N, P, I1, Q1) 
     )
  ;  Q1 is Q+1, nth_prime(N, P, I, Q1).

Teste:

30 ?- nth_prime(N,P).
N = 1,
P = 2 ;
N = 2,
P = 3 ;
N = 3,
P = 5 ;
N = 4,
P = 7 ;
N = 5,
P = 11 .

31 ?- nth_prime(N,P), N>24.
N = 25,
P = 97 ;
N = 26,
P = 101 ;
N = 27,
P = 103 .

32 ?- nth_prime(N,P), N>99.
N = 100,
P = 541 ;
N = 101,
P = 547 ;
N = 102,
P = 557 .