Neden bu iki değişkenli belirli integrali değerlendiremiyorum?

Question

Aşağıdaki iki değişkenli belirli integralin tam değerini bulmak için doğrudan x işlevini kullanmak istiyorum:

reg = ImplicitRegion[x^2 + y^2 <= 1 && x >= 0, {x, y}];
(* the answer should be π/2*Log[2] *)
Integrate[(1 + x*y)/(1 + x^2 + y^2), Element[{x, y}, reg]]

Bu iki değişkenli integral karmaşık değildir, ancak yukarıdaki formül olduğu gibi geri döner. Sorunun nerede olduğunu ve onu nasıl değiştirmem gerektiğini bilmek istiyorum.

NIntegrate[(1 + x*y)/(1 + x^2 + y^2), Element[{x, y}, reg]]
(*1.08879304515*)

Answer 1

Integrate[(1 + x*y)/(1 + x^2 + y^2), {x, y} ∈ Disk[{0, 0}, 1, {-π/2, π/2}]]

Answer 2

Alternatif bir bölge belirtimi kullanılabilir:

reg = RegionIntersection[Disk[], HalfPlane[{0, 0}, {0, 1}, {1, 0}]];
Integrate[(1 + x y)/(1 + x^2 + y^2), {x, y} ∈ reg]
   1/2 π Log[2]

veya kutupsal koordinatlara geçin:

Simplify[((1 + x y)/(1 + x^2 + y^2) /. Thread[{x, y} -> r AngleVector[θ]])
         Det[D[r AngleVector[θ], {{r, θ}}]]]
   (r + r^3 Cos[θ] Sin[θ])/(1 + r^2)

Integrate[(r + r^3 Cos[θ] Sin[θ])/(1 + r^2), {r, 0, 1}, {θ, -π/2, π/2}]
   1/2 π Log[2]