`Table`のプロットの` PlotLabel`

Question

私はTableによって与えられた2つのプロットを含んでいます

Table[
 Plot[{Re[f[n]] /. j -> 3, Im[f[n]] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, PlotRange -> All, PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel -> f[n]], 
{f, {Sum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] & , 
   (-1 + E^(2*I*Pi*#1))/(j*(-1 + E^((2*I*Pi*#1)/j))) & }}
]

ご覧のとおり、Mathematicaは最初のPlotLabel（すなわちSum[Sinc[Pi*(#1 - i*j)], {i, 1, Floor[#1]}] &）をより有用または自然であると考える式に書き直しました。私はそれがこれをすることを望まない。PlotLabelそのプロットを次のようにしたいと思います。

つまり、書かれたかのようにPlotLabel -> "expr"。しかし、他のラベルはすでに私が望む方法です。

を使って実験しましStringFormたが、役に立ちません。どうすればよいですか？それとも不可能ですか？

Answer 1

Table[Plot[{Re[ReleaseHold@f] /. j -> 3,  Im[ReleaseHold@f] /. j -> 3}, {n, 0, 15}, 
  GridLines -> Automatic, 
  PlotRange -> All, ImageSize -> 350, 
  PlotLegends -> {"Real", "Imaginary"}, 
  PlotLabel ->  f], 
{f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
   HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]

あなたは置き換えることができますHoldFormとReleaseHoldとDeferとFirst同じ結果を得るために、それぞれ、。

Bob Hanlonがコメントで示唆したように、バージョン12.0以降ではReImPlot、次のように使用できます。

 Table[ReImPlot[ReleaseHold[f] /. j -> 3, {n, 0, 15}, 
    GridLines -> Automatic, PlotRange -> All, ImageSize -> 350, 
    PlotLegends -> "ReIm", 
    ReImLabels -> {"Real", "Imaginary"}, 
    ReImStyle -> {ColorData[97][1], {ColorData[97][2], Dashing[{}]}},
    PlotLabel -> f], 
  {f, {HoldForm@Sum[Sinc[Pi*(n - i*j)], {i, 1, Floor[n]}], 
      HoldForm[(-1 + E^(2*I*Pi*n))/(j*(-1 + E^((2*I*Pi*n)/j)))]}}]