Comment tracer le vecteur magnitude-angle dans Mathematica?

Question

Je ne sais pas comment tracer ce vecteur assez simple avec une magnitude et un angle dans Mathematica. Toute aide serait appréciée. Merci d'avance.

Par exemple, 20 à 50 degrés d'angle

Answer 1

Vous pouvez utiliser la fonction AnglePath:

{x, y} = {0, 0};
r = 20;
t = 50 Degree;
Graphics[{Red, Arrow @ AnglePath[{x, y}, {{r, t}}]}]

Alternativement, vous pouvez utiliser AngleVector:

Graphics[{Red, Arrow[{{x, y}, AngleVector[{r, t}]}]}]

même image

Answer 2

Avec

{r, t} = {20, 50 Degree}

Vous pouvez toujours créer le vecteur mathématiquement avec

vec = r {Cos@t, Sin@t}

et un exemple illustratif

With[
 {pt = r {Cos@t, Sin@t}(*Mathematical implementation of the vector*)},
 Graphics[
  {
   (*Make all the lines thick*) Thickness[.007],
   (*The arrow itself*){Arrow@{{0, 0}, pt}},
   (*Arc to show label the angle*) {Circle[{0, 0}, 5, {0, 50 Degree}]},
   (*Angle label*) {Text[Style[θ == 50 Degree, 15], 4 {0.85 Cos[t/2.5], 1.1 Sin[t/2.5]}]},
   (*Magnitude label*) {Text[Style["r = 20", 15], pt {0.9, 1}]}
   }
  ]
 ]