Comment utiliser la fonction `Covariance` pour calculer correctement la covariance ?

Question

Remarque : Les questions suivantes sont tirées de la 23e question de l' examen d'entrée en mathématiques aux cycles supérieurs chinois de 2005 (première série) :

Supposer$X_{1}, X_{2}, \cdots, X_{n}(n>2)$est un échantillon aléatoire simple de la population$\mathrm{N}(0,1)$, et$\bar{X}$est la moyenne de l'échantillon ($\bar{X}=\frac{X_1+X_2+\cdots+X_n}{n}$),$Y_{i}=X_{i}-\bar{X}$,$i=1,2, \cdots, n $.

Nous devons maintenant résoudre les problèmes suivants :

(1) L'écart$D Y_{i}$de$Y_{i}$,$i=1,2, \cdots, n $.

(2) la covariance$\operatorname{Cov}\left(Y_{1}, Y_{n}\right)$de$Y_{1}$et$Y_{n}$.

J'utilise n = 10comme cas particulier pour résoudre ce problème:

Y1 = TransformedDistribution[x[1] - Sum[x[i], {i, 1, 10}]/10, 
  Table[x[i] \[Distributed] NormalDistribution[], {i, 1, 10}]]
Variance[Y1]
Y10 = TransformedDistribution[x[10] - Sum[x[i], {i, 1, 10}]/10, 
  Table[x[i] \[Distributed] NormalDistribution[], {i, 1, 10}]]
Variance[Y10]
Covariance[Y1, Y10]
Correlation[Y1, Y10]

Mais le code ci-dessus ne peut pas obtenir la covariance de Y1et Y10correctement (la réponse de référence est$-\frac{1}{10}$). Comment puis-je utiliser la fonction Covariancepour résoudre ce problème ?

Answer 1

Vous devez utiliser une notation qui sépare les variables aléatoires de leurs distributions. Le code suivant devrait vous permettre d'obtenir les variances et covariances souhaitées :

n = 10; 
distY1Yn = TransformedDistribution[{x[1] - Sum[x[i], {i, 1, n}]/n, x[n] - Sum[x[i], {i, 1, n}]/n}, 
  Table[x[i] \[Distributed] NormalDistribution[], {i, 1, n}]];
Covariance[distY1Yn]
(* {{9/10, -(1/10)}, {-(1/10), 9/10}} *)
Correlation[distY1Yn]
(* {{1, -(1/9)}, {-(1/9), 1}} *)

distY1 = TransformedDistribution[x[1] - Sum[x[i], {i, 1, n}]/n, 
   Table[x[i] \[Distributed] NormalDistribution[], {i, 1, n}]];
Variance[distY1]
(* 9/10 *)

distYn = TransformedDistribution[x[n] - Sum[x[i], {i, 1, n}]/n, 
   Table[x[i] \[Distributed] NormalDistribution[], {i, 1, n}]];
Variance[distYn]
(* 9/10 *)