管理者権限で.xlsmファイルを実行する.vbsファイルを作成したい[重複]

Question

管理者権限で.xlsmファイルを実行する.vbsファイルを作成したいと思います。

私が考えた方法は

1. 管理者としてExcelファイルを実行する
2. 管理者権限で開いたExcelから.xlsmファイルを開く

管理者として.xlsxを開きましたが、...

Set objShell = CreateObject("Shell.Application") 
objShell.ShellExecute "C:\Program Files (x86)\Microsoft Office\Office16\EXCEL.EXE", "" , "", "runas", 0

GetObject（、Excel.application）で管理者として開いた.xlsxファイルを制御できません

よろしくお願いします。

Answer 1

このvbsファイルで試してみることができます：

Option Explicit
Call Run_as_Admin() ' We execute our script with admin rights !
Dim Ws,EXCEL_FILE_PATH
Set Ws = CreateObject("Wscript.Shell")
EXCEL_FILE_PATH = "C:\Path\file.xlsm" ' Just change this line into your path file
Ws.run EXCEL_FILE_PATH,1,True
'----------------------------------------
Sub Run_as_Admin()
If Not WScript.Arguments.Named.Exists("elevate") Then
   CreateObject("Shell.Application").ShellExecute DblQuote(WScript.FullName) _
   , DblQuote(WScript.ScriptFullName) & " /elevate", "", "runas", 1
    WScript.Quit
End If
End Sub
'--------------------------------------
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'-------------------------------------