Terraform-ネストされたマップを反復処理します

Question

リソース（google_bigquery_dataset_iam_binding）を使用してBigqueryデータセットのIAMバインディングを作成しようとしています。要件は、次の構造の変数を使用して、このリソースのパラメーター（dataset_id、role、members）を読み取ることです-

  bq_iam_role_bindings = {
    "member1" = {
      "dataset1" : ["role1","role2", "role5"],
      "dataset2" : ["role3","role2"],
    },
    "member2" = {
      "dataset3" : ["role1","role4"],
      "dataset2" : ["role5"],
    } 
  }

したがって、この変数をループして、各メンバーのデータセットに割り当てられたロールを取得する必要があります。ここで作成されるリソースの合計は8つになります（各メンバー、各データセット、および各ロールに対して）。私はterraformを初めて使用し、マップ上の単純なforループとリソース内のfor_eachループを適用する方法のみを理解しています。私がやろうとしていることがどのように可能であるかを理解したい。

これは私が見つけたものに最も近いものです-ネストされたマップの値を読み取ることができるテラフォーム変数のマップ内のマップですが、私の場合もキーを抽出する必要があります。誰かここで助けてくれませんか。

Answer 1

よりfor_eachわかりやすいオブジェクトのリストに再編成して、ローカルに保存することができますhelper_list。

例えば：

variable "bq_iam_role_bindings" {

  default = {
    "member1" = {
      "dataset1" : ["role1","role2", "role5"],
      "dataset2" : ["role3","role2"],
    },
    "member2" = {
      "dataset3" : ["role1","role4"],
      "dataset2" : ["role5"],
    } 
  }
}

locals {

  helper_list = flatten([for member, value in var.bq_iam_role_bindings:
                 flatten([for dataset, roles in value: 
                           [for role in roles:
                            {"member" = member
                            "dataset" = dataset
                            "role" = role}
                         ]])
                   ])
}

これはhelper_list、次の形式になります。

[
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role1"
  },
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role2"
  },
  {
    "dataset" = "dataset1"
    "member" = "member1"
    "role" = "role5"
  },
  {
    "dataset" = "dataset2"
    "member" = "member1"
    "role" = "role3"
  },
  {
    "dataset" = "dataset2"
    "member" = "member1"
    "role" = "role2"
  },
  {
    "dataset" = "dataset2"
    "member" = "member2"
    "role" = "role5"
  },
  {
    "dataset" = "dataset3"
    "member" = "member2"
    "role" = "role1"
  },
  {
    "dataset" = "dataset3"
    "member" = "member2"
    "role" = "role4"
  },
]

上記のフォームは、次のように操作するのがはるかに簡単ですfor_each。

resource "google_bigquery_dataset_iam_binding" "reader" {

  for_each =  { for idx, record in local.helper_list : idx => record }

  dataset_id = each.value.dataset
  role       = each.value.role

  members = [
    each.value.member
  ]
}