Comment lire une chaîne à partir d'un fichier texte et l'utiliser dans un fichier de commandes Windows pour extraire une sous-chaîne

Question

Nous avons un fichier texte dont nous avons besoin contenant l'exemple suivant. Une chaîne constante "D80" suivie d'une autre chaîne:

D80KAAAAAA
D80KBBBBBB
D80KCCCCCC

Nous voulons l'extraire en utilisant un fichier de script de commandes Windows (pas PowerShell) et une boucle FOR pour obtenir cette sortie:

AAAAAA
BBBBBB
CCCCCC

Jusqu'à présent, nous sommes arrivés à ce point. Pour illustration, j'ai montré les différentes tentatives d'extraction de la sous-chaîne:

setlocal EnableDelayedExpansion

for /F "tokens=1 delims="    %%a   in (TPLIST.txt) do (
    echo %%a
    echo %%(a:~4,6)
    set substr1=%%(a:~4,6)%
    set substr2=%(a:~4,6)%
    set substr3=!(a:~4,6)!
    set substr4=%!(a:~4,6)!%
    echo %substr1%
    echo %substr2%
    echo %substr3%
    echo %substr4%
)

Cependant, l'extrait de la sous-chaîne échoue:

C:\User>setlocal EnableDelayedExpansion
C:\User>for /F "tokens=1 delims=" %a in (TPLIST.txt) do (
echo %a
 echo %(a:~4,6
)
C:\User>(
echo D80KAAAAAA
 echo %(a:~4,6
)
D80KAAAAAA
%(a:~4,6
C:\User>(
echo D80KBBBBBB
 echo %(a:~4,6
)
D80KBBBBBB
%(a:~4,6
C:\User>(
echo D80KCCCCCC
 echo %(a:~4,6
)
D80KCCCCCC
%(a:~4,6
C:\User>set substr1=%(a:~4,6)
C:\User>set substr2=~4,6)
C:\User>set substr3=!(a:~4,6)!
C:\User>set substr4=~4,6)!
C:\User>echo %(a:~4,6)
%(a:~4,6)
C:\User>echo ~4,6)
~4,6)
C:\User>echo ~4,6)
~4,6)
C:\User>echo ~4,6)
~4,6)

Toute aide serait grandement appréciée.

Answer 1

Comment extraire une sous-chaîne?

Votre script est horriblement cassé alors je l'ai réécrit:

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2,3" %%a in (test.txt) do (
  set _s1=%%a
  set _s2=%%b
  set _s3=%%c
  echo !_s1:~4!
  echo !_s2:~4!
  echo !_s3:~4!
  )
endlocal

Exemple d'utilisation:

F:\test>type test.txt
D80KAAAAAA D80KBBBBBB D80KCCCCCC

F:\test>test
AAAAAA
BBBBBB
CCCCCC
F:\test>

---

Lectures complémentaires

• Un index AZ de la ligne de commande Windows CMD | SS64.com
• Commandes Windows CMD (catégorisées) - Windows CMD - SS64.com
• For / f - Boucle sur du texte - Windows CMD - SS64.com
• sous-chaîne variable - Windows CMD - SS64.com

Answer 2

Dans le fichier de commandes Pure, vous pouvez faire quelque chose comme ça:

@echo off
Set "InputFile=TPLIST.txt"
Set "OutPutFile=%~dp0Out-Extract.txt"

setlocal enabledelayedexpansion
> "%OutPutFile%" (
    @for /f "delims=" %%a in ('Type "%InputFile%"') do (
    set "_MyString=%%a"
    echo !_MyString:~4!
    )
)
endlocal
If Exist "%OutPutFile%" Start "" "%OutPutFile%"

---

Dans Powershell, si un autre membre veut tester en utilisant RegEx:

cls
$MyString = @' D80KAAAAAA D80KBBBBBB D80KCCCCCC D80KDDDDDD D80KEEEEEE D80KFFFFFF D80KXXXXXX D80KYYYYYY D80KZZZZZZ '@ -split [System.Environment]::NewLine $pattern = '(?![D80K]).+'
$MyString | %{ [regex]::matches($_,$pattern) } | %{ $_.Groups[0].Value }

---

Vous obtiendrez en sortie pour les deux solutions batch ou powershell comme ça:

AAAAAA
BBBBBB
CCCCCC
DDDDDD
EEEEEE
FFFFFF
XXXXXX
YYYYYY
ZZZZZZ