Come ordinare / estrarre i poteri positivi e negativi come elenco?

Question

Ho la seguente espressione

expr = x1^d1 * x2^d2 * x3^d3;

dove d1,d2,d3può contenere valori / espressioni negativi, ovvero in generale questi d1,d2,d3potrebbero non essere valori numerici. Dire

d1 = 4 d;
d2 = -5 e;
d3 =  -6 d;
with assumption d, e are positive.

Domanda: esiste un modo per creare due elenchi uno contenente esponente positivo e l'altro con esponente negativo?

Il mio tentativo attuale è quello di utilizzare Exponentciascuno di questi termini e testarli per positivo e negativo.

Answer 1

$Version

(* "12.1.1 for Mac OS X x86 (64-bit) (June 19, 2020)" *)

Clear["Global`*"]

expr = x1^d1*x2^d2*x3^d3;

exponents = 
 Cases[expr, x_^p_. :> p, 1] /. {d1 -> 4 d, d2 -> -5 e, d3 -> -6 d}

(* {4 d, -5 e, -6 d} *)

pos = Assuming[{d > 0, e > 0}, Select[exponents, Simplify[# > 0] &]]

(* {4 d} *)

neg = Assuming[{d > 0, e > 0}, Select[exponents, Simplify[# < 0] &]]

(* {-5 e, -6 d} *)

Answer 2

È inoltre possibile utilizzare Internal`SyntacticNegativeQcon GeneralUtilities`SelectDiscard, GroupBy, Cases, DeleteCases, Selecto Pickcome segue:

expr = x1^d1*x2^d2*x3^d3

x1^(4 d) x2^(-5 e) x3^(-6 d)

exponents = Exponent[expr, {x1, x2, x3}]

{4 d, -5 e, -6 d}

{neg, pos} = GeneralUtilities`SelectDiscard[Internal`SyntacticNegativeQ] @ exponents

{neg, pos} = GroupBy[exponents, Internal`SyntacticNegativeQ] /@ {True, False}

{neg, pos} = Cases[#@_?Internal`SyntacticNegativeQ]@exponents & /@ 
   {Identity, Except}

{neg, pos} = DeleteCases[#@_?Internal`SyntacticNegativeQ] @ exponents & /@ 
   {Except, Identity}

{neg, pos} = Select[#@*Internal`SyntacticNegativeQ]@exponents & /@ 
   {Identity, Not}

{neg, pos} = Pick[exponents, 
    Internal`SyntacticNegativeQ /@ exponents, #] & /@ {True, False}

tutti danno

 {{-5 e, -6 d}, {4 d}}