Crea variabili in un ciclo for

Question

Sono molto nuovo in matematica, ma sarebbe molto più facile per me usare i cicli For per creare variabili. Il mio pensiero era semplice, ma a quanto pare non funziona. Diciamo che ho definito queste variabili

ex1 = 1 + 0.5
ex2 = ex1 + 0.5^2/2!
ex3 = ex2 + 0.5^3/3!
ex4 = ex3 + 0.5^4/4!
ex5 = ex4 + 0.5^5/5!
ex6 = ex5 + 0.5^6/6!

Il passo successivo nella mia classe di metodi numerici è stato ottenere l'errore assoluto, il che significa sottrarre il valore reale dal valore sperimentale che otterrei da "ex1", per esempio. Ciò che stiamo cercando di approssimare qui è e^0.5, tra l'altro.

Quindi quello che ho fatto prima è stato:

ae1 = (e^0.5 - ex1)

E ho appena ripetuto quel passaggio per tutti loro. Mi piacerebbe introdurli in un ciclo For, tuttavia, in cui definisco le variabili e utilizzo le variabili passate nel ciclo. Il mio pensiero è stato:

For[i = 1, i < 7, i++, Print[aei = (e^0.5 - exi)]]

Questo ovviamente non funziona, ma è possibile fare qualcosa del genere?

Answer 1

Che ne dici di definirlo in modo ricorsivo?

ex[0] = 1;
ex[n_] := ex[n] = ex[n - 1] + 0.5^n/n!;

La doppia assegnazione nella seconda riga è molto importante. Ciò fa sì che tutte le chiamate di funzione vengano valutate una sola volta. Una volta valutato inizialmente, verrà salvato in ex[n].

Table[{k, ex[k]}, {k, 1, 10}] // TableForm

1 1.5
2 1.625
3 1.64583
4 1.64844
5 1,6487
6 1.64872
7 1.64872
8 1.64872
9 1.64872
10 1.64872

Answer 2

Clear["Global`*"]

Continuando con il suggerimento di infinitezero di usare la ricorsione, usa RSolveper trovare l'espressione generale.

ex[n_] = ex[n] /. 
  RSolve[{ex[0] == 1, ex[n] == ex[n - 1] + (1/2)^n/n!}, ex[n], n][[1]]

(* (Sqrt[E] Gamma[1 + n, 1/2])/Gamma[1 + n] *)

I primi diversi valori sono

ex /@ Range[0, 10] *)

(* {1, 3/2, 13/8, 79/48, 211/128, 6331/3840, 75973/46080, 354541/215040, \
17017969/10321920, 306323443/185794560, 2042156287/1238630400}

Che sono approssimativamente,

% // N

(* {1., 1.5, 1.625, 1.64583, 1.64844, 1.6487, 1.64872, 1.64872, 1.64872, \
1.64872, 1.64872} *)

%[[-1]] // InputForm

(* 1.6487212706873657 *)

Il limite di questa sequenza è

Limit[ex[n], n -> Infinity]

(* Sqrt[E] *)

% // N[%, 20] &

(* 1.6487212707001281468 *)

Answer 3

Un altro modo, usando FoldList:

FoldList[#1 + 0.5^#2/#2! &, 1 , Range[7]]
(* {1, 1.5, 1.625, 1.64583, 1.64844, 1.6487, 1.64872, 1.64872} *)