Creazione di una tabella con profondità variabile e limiti interdipendenti

Question

Ad esempio, voglio trovare tutti i numeri interi fino a un dato limite che hanno solo determinati fattori primi. Posso farlo in modo efficiente per il caso di 2, 3 e 5 di

g = 100;
t1 = Table[{2^x*3^y*5^z}, {z, 0, Log[g]/Log[5]}, {y, 0, Log[g/(5^z)]/Log[3]}, {x, 0, Log[g/(5^z*3^y)]/Log[2]}]
t2 = Sort[Flatten[t1]]

Ma sto cercando una soluzione più generale in cui potrei avere un insieme di k diversi fattori. Ho provato Nestma non sono andato lontano. E non voglio usare una funzione come FactorIntegere poi Selectquelle buone. Sto cercando una soluzione che combini profondità Tablee (forse) funzione ricorsiva dei limiti.

Answer 1

Forse stai cercando numeri fluidi . La funzione pSmoothOuterè abbastanza veloce, ma richiede memoria poiché il limite superiore mdiventa più grande. L'input pmaxè il numero massimo consentito.

pSmoothOuter[pmax_Integer, m_] :=
   Block[{s},
      s = 2^Range[0, Log[2, m]];
      Do[
         s = Pick[s = Flatten[Outer[Times, s, p^Range[0, Log[p, m]]]], UnitStep[m - s], 1],
         {p, Prime[Reverse[Range[2, PrimePi[pmax]]]]}];
      Sort[s]]

Per esempio,

pSmoothOuter[5,10^2]

{1, 2, 3, 4, 5, 6, 8, 9, 10, 12, 15, 16, 18, 20, 24, 25, 27, 30, 32,
36, 40, 45, 48, 50, 54 , 60, 64, 72, 75, 80, 81, 90, 96, 100}

AbsoluteTiming[{Total[#], Length[#]} &[pSmoothOuter[30, 10^8]]]

{0.015348, {2364148327261, 88415}}

La seguente versione consente un elenco di input di numeri primi p, non necessariamente contigui.

pSmoothOuter[p_List, m_] :=
   Block[{s},
      s = Min[p]^Range[0, Log[Min[p], m]];
      Do[
         s = Pick[s=Flatten[Outer[Times, s, q^Range[0, Log[q, m]]]], UnitStep[m - s], 1],
         {q, Most@Reverse[Sort[p]]}];
      Sort[s]]

Per esempio,

pSmoothOuter[{5, 13, 11}, 800]

{1, 5, 11, 13, 25, 55, 65, 121, 125, 143, 169, 275, 325, 605, 625, 715}

Answer 2

Questo dovrebbe funzionare. La costruzione è ingombrante e può essere semplificata, ma almeno funziona:

makePrimes[numPrimes_, bound_] := Module[
  {powers = (Prime@Range[numPrimes])^Array[x, numPrimes] // Reverse},
  Sort@Flatten@Table[
    Times @@ powers // Evaluate,
    Sequence @@ MapThread[{#1, 0, #2} &,
      {Reverse@Array[x, numPrimes], 
       Log[bound/Prepend[Most@Exp@Accumulate@Log@powers, 1]]/Reverse@Log@Prime@Range[numPrimes]}
    ] // Evaluate
  ]
]

Poi

makePrimes[3, 100]
(* {1, 2, 3, 4, 5, 6, 8, 9, 10, 12, 15, 16, 18, 20, 24, 25, 27, 30, 32, 36, 40, 45, 48, 50, 54, 60, 64, 72, 75, 80, 81, 90, 96, 100} *)

è lo stesso elenco dell'esempio dell'OP.