Comment renommer un bouton ActiveX nouvellement créé?

Question

Selon la réponse de Mathieu , j'ai réussi à créer un bouton ActiveX via

Sub aaaaaaaa()
Dim newButton As Object
Set newButton = Sheets(sheetname_KvE).OLEObjects.Add(ClassType:="Forms.CommandButton.1", _
    Link:=False, _
    DisplayAsIcon:=False, _
    Left:=800, _
    Top:=0, _
    Width:=300, _
    Height:=30).Object
With newButton
    .Caption = "bla"
    '.Name = "Button_what" ' - THIS DOES NOT WORK!
End With
End Sub

Comment puis-je renommer ce bouton?

Malheureusement, ces liens ne m'ont pas conduit à la solution:

• Modification du nom d'une zone de liste Excel ActiveX

• https://answers.microsoft.com/en-us/msoffice/forum/all/vba-code-to-modify-the-name-property-of-an-activex/d23b4ee5-aef4-425b-8a19-2899b65651e2

Ce serait assez glorieux, car cela permet d'ajouter du code pertinent dans le module de la feuille (pour autant que je sache, le sous-jacent pertinent est toujours appelé [insert button name]_Click).

Answer 1

Est-ce ce que vous essayez?

Sub Sample()
    Dim newButton As OLEObject
    Dim ws As Worksheet
    
    Set ws = Sheets(sheetname_KvE)
    Set newButton = ws.OLEObjects.Add(ClassType:="Forms.CommandButton.1", _
                                      Link:=False, _
                                      DisplayAsIcon:=False, _
                                      Left:=800, _
                                      Top:=0, _
                                      Width:=300, _
                                      Height:=30)
    newButton.Object.Caption = "bla"
    newButton.Name = "Button_what"
End Sub