Résolution d'une équation différentielle complexe avec ParametricNDSolveValue

Question

J'essaye de résoudre une équation différentielle complexe pour la fonction $S(u,v)$ en fonction du paramètre $\omega$. Le code est:

ClearAll["Global`*"]
m = 100;
L = 2;
r[u_, v_] = 2 m (1 + ProductLog[- ((u v)/E)]);
F[u_, v_] = (32 m^3)/r[u, v]^3 Exp[-(r[u, v]/(2 m))];
Vz[u_, v_] = FullSimplify [-2 (D[F[u, v], u] D[F[u, v], v])/F[u, v] + 
    4 D[r[u, v], u, v]/r[u, v] + 2/F[u, v] D[F[u, v], u, v] + 
    2/F[u, v] D[F[u, v], u] D[r[u, v], v] + 
    2/F[u, v] D[F[u, v], v] D[r[u, v], u]];
Z[u_, v_] = Exp[-I (u + v)/2 ω] S[u, v];
sol = ParametricNDSolveValue[{D[Z[u, v], u, v] + 
     F[u, v] (L (L + 1))/r[u, v]^2 Z[u, v] + Z[u, v] Vz[u, v] == 0, 
   S[u, -1] == 1, S[1, v] == 1}, 
  S, {u, 1, 100}, {v, -100, -1}, ω]

J'obtiens l'erreur

ParametricNDSolveValue :: mconly: "Pour la méthode! (" IDA "), seul le code réel de la machine est disponible. Impossible de continuer avec des valeurs complexes ou au-delà des exceptions en virgule flottante"

Il semble donc que Mathematica attend des nombres réels, mais trouve plutôt des nombres complexes. Comment puis-je résoudre l'équation différentielle?

Answer 1

Cette question peut être résolue en résolvant Zplutôt qu'en Sdivisant la PDE en ses parties réelle et imaginaire, et en la construisant plus tard Ssi on le souhaite.

solr[ω_] := NDSolveValue[{D[Z[u, v], u, v] + 
    F[u, v] (L (L + 1))/r[u, v]^2 Z[u, v] + Z[u, v] Vz[u, v] == 0, 
    Z[u, -1] == Cos[1/2 (-1 + u) ω], Z[1, v] == Cos[1/2 (1 + v) ω]}, 
    Z, {u, 1, 2}, {v, -2, -1}]
soli[ω_] := NDSolveValue[{D[Z[u, v], u, v] + 
    F[u, v] (L (L + 1))/r[u, v]^2 Z[u, v] + Z[u, v] Vz[u, v] == 0, 
    Z[u, -1] == -Sin[1/2 (-1 + u) ω], Z[1, v] == -Sin[1/2 (1 + v) ω]}, 
    Z, {u, 1, 2}, {v, -2, -1}]

zr = solr[1];
Plot3D[zr[u, v], {u, 1, 2}, {v, -2, -1}, PlotRange -> All, 
    ImageSize -> Large, AxesLabel -> {u, v, z}, LabelStyle -> {15, Black, Bold}]

zi = soli[1];
Plot3D[zi[u, v], {u, 1, 2}, {v, -2, -1}, PlotRange -> All, 
    ImageSize -> Large, AxesLabel -> {u, v, z}, LabelStyle -> {15, Black, Bold}]

Deux notes. Premièrement, les plages d'intégration de uet vont été considérablement réduites, car la solution augmente de façon exponentielle dans le cas contraire et Plot3Déchoue. Deuxièmement, utiliser ParametricNDSolveValueau lieu de SetDelayedet NDSolveValuefait planter le noyau.