TerraformAWS-EC2セキュリティグループ

Question

Terraformについてもっと学ぶのに忙しいのですが、回避策や修正方法がわからないという問題が1つあります。

問題は次のとおりです。私のスクリプトでは、en EIPやモジュールからのセキュリティグループなど、いくつかの副次的なものを含むec2インスタンス（AWS）を生成していますが、これらはすべて正常に機能しています。しかし、セキュリティグループをマシンにアタッチする方法がわかりません。現在、セキュリティグループが作成されており、それだけです。

コードは次のとおりです。

data "aws_ami" "latest" {
  most_recent = true
  owners = [ "self"] 

    filter {
      name = "name"
      values = [ lookup(var.default_ami, var.ami) ]
    }
}

module "aws_security_group" {
  source = "./modules/services/Security groups/"
  server_port = 443
}

resource "aws_instance" "test-ec2deployment" {
  ami                           = data.aws_ami.latest.id
  instance_type                 = var.instance_type
  subnet_id                     = var.subnet_id
  availability_zone             = var.availability_zone
  associate_public_ip_address   = var.public_ip
  
  root_block_device {
    volume_type                 = "gp2"
    volume_size                 = 60
    delete_on_termination       = true
  }
  
   tags = {
    Name                        = "Testserver2viaTerraform"
  }
}

resource "aws_eip" "ip" {
  instance = aws_instance.test-ec2deployment.id
}

resource "aws_eip" "example" {
  vpc = true
}

上記はメインファイルで、次のモジュールをロードしています。

resource "aws_security_group" "my-webserver" {
  name        = "webserver"
  description = "Allow HTTP from Anywhere"
  vpc_id      = "vpc-"
  ingress {
    from_port   = 80
    to_port     = 80
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }
  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
  tags = {
    Name = "my-webserver"
    Site = "my-web-site"
  }
}

最後のステップは、セキュリティグループをマシンに接続することですが、これを行う方法についての手がかりはありません。私はいくつかのドキュメントを読んでグーグルしようとしましたが、答えが見つからないか、答えがうまくいきません。だからうまくいけば、皆さんは私をさらに助けることができます。

お時間をいただき、ありがとうございました。

Answer 1

aws_security_groupモジュールで、。/ modules / services / Security groups // main.tfに以下を追加して、セキュリティグループIDを出力する必要があります。

output "securitygroup_id" {
  value = aws_security_group.my-webserver.id
}

次に、メインのtfファイルで、次のようにセキュリティグループをインスタンスにアタッチします。

resource "aws_network_interface_sg_attachment" "sg_attachment" {
  security_group_id    = module.aws_security_group.securitygroup_id
  network_interface_id = aws_instance.test-ec2deployment.primary_network_interface_id
}