การแก้สมการเชิงอนุพันธ์ที่ซับซ้อนด้วย ParametricNDSolveValue

Question

ฉันกำลังพยายามแก้สมการเชิงอนุพันธ์ที่ซับซ้อนสำหรับฟังก์ชัน $S(u,v)$ ขึ้นอยู่กับพารามิเตอร์ $\omega$. รหัสคือ:

ClearAll["Global`*"]
m = 100;
L = 2;
r[u_, v_] = 2 m (1 + ProductLog[- ((u v)/E)]);
F[u_, v_] = (32 m^3)/r[u, v]^3 Exp[-(r[u, v]/(2 m))];
Vz[u_, v_] = FullSimplify [-2 (D[F[u, v], u] D[F[u, v], v])/F[u, v] + 
    4 D[r[u, v], u, v]/r[u, v] + 2/F[u, v] D[F[u, v], u, v] + 
    2/F[u, v] D[F[u, v], u] D[r[u, v], v] + 
    2/F[u, v] D[F[u, v], v] D[r[u, v], u]];
Z[u_, v_] = Exp[-I (u + v)/2 ω] S[u, v];
sol = ParametricNDSolveValue[{D[Z[u, v], u, v] + 
     F[u, v] (L (L + 1))/r[u, v]^2 Z[u, v] + Z[u, v] Vz[u, v] == 0, 
   S[u, -1] == 1, S[1, v] == 1}, 
  S, {u, 1, 100}, {v, -100, -1}, ω]

ฉันได้รับข้อผิดพลาด

ParametricNDSolveValue :: mconly: "สำหรับวิธีการ! (" IDA ") จะใช้ได้เฉพาะรหัสจริงของเครื่องเท่านั้นไม่สามารถดำเนินการต่อด้วยค่าที่ซับซ้อนหรือเกินกว่าข้อยกเว้นทศนิยม"

ดูเหมือนว่า Mathematica คาดหวังจำนวนจริง แต่พบจำนวนเชิงซ้อนแทน ฉันจะแก้สมการเชิงอนุพันธ์ได้อย่างไร

Answer 1

คำถามนี้สามารถแก้ไขได้โดยการแก้ปัญหาZแทนที่จะSแยก PDE ออกเป็นส่วนจริงและส่วนจินตภาพและสร้างในภายหลังSหากต้องการ

solr[ω_] := NDSolveValue[{D[Z[u, v], u, v] + 
    F[u, v] (L (L + 1))/r[u, v]^2 Z[u, v] + Z[u, v] Vz[u, v] == 0, 
    Z[u, -1] == Cos[1/2 (-1 + u) ω], Z[1, v] == Cos[1/2 (1 + v) ω]}, 
    Z, {u, 1, 2}, {v, -2, -1}]
soli[ω_] := NDSolveValue[{D[Z[u, v], u, v] + 
    F[u, v] (L (L + 1))/r[u, v]^2 Z[u, v] + Z[u, v] Vz[u, v] == 0, 
    Z[u, -1] == -Sin[1/2 (-1 + u) ω], Z[1, v] == -Sin[1/2 (1 + v) ω]}, 
    Z, {u, 1, 2}, {v, -2, -1}]

zr = solr[1];
Plot3D[zr[u, v], {u, 1, 2}, {v, -2, -1}, PlotRange -> All, 
    ImageSize -> Large, AxesLabel -> {u, v, z}, LabelStyle -> {15, Black, Bold}]

zi = soli[1];
Plot3D[zi[u, v], {u, 1, 2}, {v, -2, -1}, PlotRange -> All, 
    ImageSize -> Large, AxesLabel -> {u, v, z}, LabelStyle -> {15, Black, Bold}]

สองบันทึก ประการแรกช่วงการรวมuและvลดลงอย่างมากเนื่องจากโซลูชันมีขนาดใหญ่ขึ้นอย่างมากและPlot3Dล้มเหลว ประการที่สองการใช้ParametricNDSolveValueแทนSetDelayedและNDSolveValueทำให้เคอร์เนลผิดพลาด