Comment puis-je ingérer et analyser les résultats de référence publiés sur MSE?

Nov 26 2020

Comment puis-je ingérer des résultats de référence Mathematica / WL publiés sur Mathematica Stack Exchange (MSE), comme ceux affichés ici ?

Hypothèses:

Il y a plusieurs réponses avec des repères affichés
Les résultats de référence ont une certaine forme claire de «liste de règles»

Voir:

Needs["Benchmarking`"]
Benchmark[]

(* {"MachineName" -> "macbook-pro", "System" -> "Mac OS X x86 (64-bit)", "BenchmarkName" -> "WolframMark", "FullVersionNumber" -> "12.1.1", "Date" -> "November 26, 2020",
 "BenchmarkResult" -> 3.028, "TotalTime" -> 4.571, "Results" -> {{"Data Fitting", 0.291}, {"Digits of Pi", 0.249}, {"Discrete Fourier Transform", 0.363}, {"Eigenvalues of a Matrix", 0.297},
   {"Elementary Functions", 0.375}, {"Gamma Function", 0.356}, {"Large Integer Multiplication", 0.323}, {"Matrix Arithmetic", 0.227}, {"Matrix Multiplication", 0.218}, {"Matrix Transpose", 0.404},
   {"Numerical Integration", 0.463}, {"Polynomial Expansion", 0.068}, {"Random Number Sort", 0.449}, {"Singular Value Decomposition", 0.221}, {"Solving a Linear System", 0.267}}} *)

Réponses

12 AntonAntonov Nov 26 2020 at 18:23

Ingestion

Obtenez toutes les réponses de la discussion MSE dans un objet XML:

xmlObject = 
  Import["https://mathematica.stackexchange.com/questions/234881/benchmarking-with-mathematica-v-12-for-up-to-date-comparision-of-mathematica-acr/235384#235384", "XMLObject"];

Obtenez des éléments XML de code:

lsRes1 = Cases[xmlObject, XMLElement["code", {}, code_] :> code, \[Infinity]];

(Notez qu'à ce stade, les chaînes de code sont obtenues.)

Supprimez Benchmarkles commandes de calcul et convertissez les chaînes de code en code WL:

lsRes2 = Map[
   ToExpression@
     StringReplace[#, {"BenchmarkReport[]" -> "", "Benchmark[]" -> ""}] &, lsRes1];
Length[lsRes2]

(*16*)

Sélectionnez le code (blocs) qui sont des listes de règles:

lsRes3 = Select[Flatten /@ lsRes2, MatchQ[#, {_Rule ..}] && Length[#] > 1 &];
Length[lsRes3]

(*10*)

Pour chaque bloc de code, aplatissez les métadonnées et les résultats de référence en associations:

lsRes4 = Map[Association@ Cases[Flatten[# /.  HoldPattern["Results" -> r_] :> (Rule @@@ r)], _Rule] &, lsRes3];
Length[lsRes4]

(*10*)

Assurez-vous que toutes les associations ont les mêmes clés:

lsRes5 = 
 Block[{lsAllKeys = Union[Flatten[Keys /@ lsRes4]]}, 
  Map[Join[AssociationThread[lsAllKeys, "NA"], #] &, lsRes4]
 ];
Length[lsRes5]

(*10*)

(Sinon, l'ensemble de données obtenu peut être difficile à utiliser dans certains calculs.)

Créez un jeu de données de comparaison:

dsBenchmarks = Dataset[lsRes5];
dsBenchmarks = dsBenchmarks[SortBy[#BenchmarkResult &]]

Analyse de base

Résumez l'ensemble de données:

ResourceFunction["RecordsSummary"][dsBenchmarks]

(Bar) Résultats du tracé:

Multicolumn@
 KeyValueMap[
  If[VectorQ[#2, NumericQ], 
    BarChart[#2, PlotLabel -> #1, PlotTheme -> "Detailed"], 
    Nothing
  ] &, 
  Normal@Transpose@dsBenchmarks
]

Statistiques de ventilation

Résultats du benchmark de partition par système (ou autres critères):

aRes = GroupBy[Normal@dsBenchmarks, #System &, Dataset];
aRes = Map[#[All, Select[#, NumericQ] &] &, aRes];

Séparez les résultats globaux du benchmark des résultats des composants de référence:

aRes2 = Map[#[All, KeyTake[#, {"BenchmarkResult", "TotalTime"}] &] &, aRes];
aRes3 = Map[#[All, KeyDrop[#, {"BenchmarkResult", "TotalTime"}] &] &, aRes];

Afficher les résultats globaux du benchmark:

aRes2

Afficher les graphiques statistiques de distribution par système:

aResPlots3 = 
  BoxWhiskerChart[Transpose[Normal[#[Values]]], 
     PlotLabel -> Row[{"Number of benchmarks:", Spacer[2], Length[#]}], 
     ChartStyle -> 56, ImageSize -> Medium, PlotTheme -> "Detailed", 
     ChartLegends -> Keys[Normal@#[[1]]]] & /@ aRes3;
Grid[List @@@ Normal[aResPlots3], Dividers -> All, FrameStyle -> GrayLevel[0.7]]