Tabela nad indeksami tablicy

Question

Chcę uogólnić poniższą tabelę na podsumowanie $s[1], \ldots, s[N]$ i $t[1], \ldots t[N]$, gdzie sumuje się każda zmienna $\{-1, 1\}$.

Table[ expr , {s[1], {-1, 1}}, {s[2], {-1, 1}},  {s[3], {-1, 1}}, {t[1], {-1, 1}}, t[2], {-1, 1}}, {t[3], {-1, 1}} ]

Wyrażenie zależy od obu tablic $s$ i $t$ w jakiś skomplikowany sposób.

Zasadniczo zamiast wypisywać sumy na każdym z indeksów tablicy $s[1], s[2], s[3], t[1], t[2], t[3]$jak mogę to napisać w sposób ogólny w zależności od parametru N?

Answer 1

Myślę, że to jest sedno lub twoje pytanie:

Clear[s, t]
n = 3;
vars = Join[Array[Indexed[s, #] &, n], Array[Indexed[t, #] &, n]];
vals = Tuples[{-1, 1}, 2 n];  (* the possible configs *)
rules = Thread[Rule[vars, #]] & /@ vals;  (* rules linking vars to each config *)
vars /. rules  (* an expression in the vars, at each config *)

Answer 2

Oto sposób bez wycieków oceny: (tj. Będzie działać, nawet jeśli s[1]itp. Mają wartości poza Table)

n = 3;
Replace[
  Join[s /@ Hold @@ Range@n, t /@ Hold @@ Range@n],
  v_ :> {v, {-1, 1}},
  1
  ] /.
 Hold[s___] :> Hold@Table[(*remove Hold to evaluate*)
    expr,
    s
    ]
(* Hold[
 Table[expr, {s[1], {-1, 1}}, {s[2], {-1, 1}}, {s[3], {-1, 1}}, {t[
    1], {-1, 1}}, {t[2], {-1, 1}}, {t[3], {-1, 1}}]] *)

Jak wspomniano w powyższym komentarzu, musisz usunąć, Holdaby tabela mogła ocenić. Aby zobaczyć, jak to działa, pokażę niektóre z poszczególnych kroków powyższego wyrażenia:

(* list of s "variables" *)
s /@ Hold @@ Range@n
(* Hold[s[1], s[2], s[3]] *)

(* combine with t "variables" *)   
Join[s /@ Hold @@ Range@n, t /@ Hold @@ Range@n]
(* Hold[s[1], s[2], s[3], t[1], t[2], t[3]] *)

(* insert the iterator specifications *)
Replace[
 Join[s /@ Hold @@ Range@n, t /@ Hold @@ Range@n],
 v_ :> {v, {-1, 1}},
 1
 ]
(* Hold[{s[1], {-1, 1}}, {s[2], {-1, 1}}, {s[3], {-1, 1}}, {t[
   1], {-1, 1}}, {t[2], {-1, 1}}, {t[3], {-1, 1}}] *)

Jeśli nie przejmujesz się wyciekami ewaluacyjnymi, to wystarczy:

n = 3;
Hold@Table[expr, ##] & @@ (
  {#, {-1, 1}} & /@ Join[s /@ Range@n, t /@ Range@n]
  )
(* Hold[
 Table[expr, {s[1], {-1, 1}}, {s[2], {-1, 1}}, {s[3], {-1, 1}}, {t[
    1], {-1, 1}}, {t[2], {-1, 1}}, {t[3], {-1, 1}}]] *)

Ponownie, musisz usunąć blokadę w swoim rzeczywistym kodzie.

Możesz również rozważyć użycie, Arrayjeśli możesz zmienić sposób używania zmiennych:

n = 3;
Array[f[##] &, ConstantArray[2, n], {-1, 1}]
(* {{{f[-1, -1, -1], f[-1, -1, 1]}, {f[-1, 1, -1], 
   f[-1, 1, 1]}}, {{f[1, -1, -1], f[1, -1, 1]}, {f[1, 1, -1], 
   f[1, 1, 1]}}} *)

Tutaj funkcja fpo prostu pobiera wartości s[…]i t[…]w kolejności.

Answer 3

@Alan podał elegancki sposób rozwiązania problemu.

Tutaj wystarczy wspomnieć, że oryginalne wyrażenie:

Table[expr[s1, s2, s3, t1, t2, t3], {s1, {-1, 1}}, {s2, {-1, 1}}, {s3, {-1, 1}}, {t1, {-1,1}}, {t2, {-1, 1}}, {t3, {-1, 1}}]

jest równa

Outer[expr, {-1, 1}, {-1, 1}, {-1, 1}, {-1, 1}, {-1, 1}, {-1, 1}]