BarChart - Zachowaj ChartElementFunction podczas zmiany PlotRange

Question

Oto BarChartniektóre dane

data = {90, 91, 95, 103, 107, 102, 107, 105, 98, 96}

{90, 91, 95, 103, 107, 102, 107, 105, 98, 96}

BarChart[data, ChartElementFunction -> "GradientScaleRectangle"]

Kiedy dodam, PlotRangekolor znika.

BarChart[data, ChartElementFunction -> "GradientScaleRectangle", 
 PlotRange -> {80, 120}]

Czy można to obejść?

Answer 1

Możemy użyć niestandardowego, ChartElementFunctionaby przyciąć prostokąty:

ClearAll[cEF]
cEF[cedf_: "GradientScaleRectangle", o: OptionsPattern[]][d_, pr_] := 
 Block[{Charting`ChartStyleInformation}, 
   Charting`ChartStyleInformation["BoundingBox"] = 
      {{.5, Length @ d + .5}, {pr[[1]], Max @ d}};
   ChartElementDataFunction[cedf, o][{#[[1]], Clip[#[[2]], pr]}, ##2]] &;

Przykłady:

data = {90, 91, 95, 103, 107, 102, 107, 105, 98, 96};
plotrange = {80, 120};

BarChart[data, 
 ChartElementFunction -> cEF[][data, plotrange], 
 ChartLabels -> CharacterRange["A", "J"],  
 PlotRange -> plotrange, 
 ImagePadding -> 20]

Użyj, cEF["GradientScaleRectangle", "ColorScheme" -> "Rainbow"][data, plotrange]aby uzyskać:

BarChart[data, ColorFunction -> "Rainbow", 
 ChartElementFunction -> 
    cEF["GlassRectangle", "GradientOrigin" -> Top][data, {75, 110}], 
 ChartLabels -> CharacterRange["A", "J"],  
 PlotRange -> {75, 110}, 
 ImagePadding -> 20]

BarChart[data, 
 ChartStyle -> (Texture[ExampleData[{"TestImage", #}]] & /@ {"Lena", "Mandrill"}),
 ChartElementFunction -> cEF["TextureRectangle"][data, {70, 110}], 
 ChartLabels -> CharacterRange["A", "J"],  
 PlotRange -> {70, 110}, 
 ImagePadding -> 20, ImageSize -> Large]

Aktualizacja: Alternatywne podejście wykorzystujące zmodyfikowane dane wejściowe i niestandardowe znaczniki oraz dopełnienie zakresu wykresu:

plotrange = {80, 120};
data2 = data - plotrange[[1]];
plotrange2 = {0, - Subtract @@ plotrange};
padding = plotrange2[[2]] - Max @ data2;

BarChart[Thread[Tooltip[data2, data]],
 ChartElementFunction -> "GradientScaleRectangle",
 ChartLabels -> CharacterRange["A", "J"],
 PlotRangePadding -> {{Automatic, Automatic}, {Automatic, padding}},
 Ticks -> {Automatic, Charting`FindTicks[plotrange2, plotrange]}]

Answer 2

data = {90, 91, 95, 103, 107, 102, 107, 105, 98, 96};
Show[BarChart[data,
  ChartElementFunction -> "GradientScaleRectangle"],
 PlotRange -> {80, 120}]

Kreślenie kolorów od niebieskiego do pomarańczowego poprzez dostosowanie danych i etykiet znaczników.

data = {90, 91, 95, 103, 107, 102, 107, 105, 98, 96} - 80;
Show[BarChart[data,
  ChartElementFunction -> "GradientScaleRectangle",
  Ticks -> {Automatic,
    {{0, 80}, {10, 90}, {20, 100}, {30, 110}, {40, 120}}}],
 PlotRange -> {0, 40}]