Jak liczyć n-tą liczbę pierwszą w prologu

Question

Jestem całkiem nowy w prologu i próbuję napisać predykat, który podaje wartość n-tej liczby pierwszej i tak wygląda nth_prime(N, Prime) . Wykonałem już funkcję, która liczy, czy liczba jest liczbą pierwszą, czy nie

div(X, Y):- 0 is X mod Y.
div(X, Y):- X>Y+1, Y1 is Y+1, div(X, Y1).

prime(2):- true.
prime(X):- X<2, false.
prime(X):- not(div(X, 2)).

Nie rozumiem, jaki jest mój następny krok i jak mam policzyć, która liczba pierwsza należy do N.

Answer 1

Twój kod jest trochę nietypowy dla prologu, ale (z wyjątkiem prime(1)) działa.

Oto rozwiązanie dla twojego predykatu:

nextprime(N,N):- 
    prime(N),
    !.
nextprime(P, Prime):-
    PP is P+1,
    nextprime(PP,Prime).

nthprime(1, 2).
nthprime(N, Prime):-
    N>1,
    NN is N-1,
    nthprime(NN, PrevPrime),
    PP is PrevPrime+1,
    nextprime(PP, Prime).

?- nthprime(1,P).
P = 2 ;
false.

?- nthprime(2,P).
P = 3 ;
false.

?- nthprime(3,P).
P = 5 ;
false.

Działa to następująco: Wiadomo, że pierwsza liczba pierwsza to 2 ( nthprime(1, 2).). Dla każdej innej liczby Nwiększej niż 1uzyskaj poprzednią liczbę pierwszą ( nthprime(NN, PrevPrime)), dodaj 1, aż trafisz na liczbę pierwszą. Dodanie 1 części odbywa się za pomocą predykatu pomocy nextprime/2: dla podanej liczby Psprawdza, czy ta liczba jest liczbą pierwszą. Jeśli tak, zwraca tę liczbę, w przeciwnym razie wywoła siebie po następną wyższą liczbę ( nextprime(PP,Prime)) i przekaże wynik. Huk !nazywany jest cięciem, które przecina inne gałęzie. Więc jeśli raz trafisz na liczbę pierwszą, nie możesz wrócić i spróbować innej ścieżki.

Aby to przetestować, możesz poprosić ?- nthprime(N,P).o dane N. Lub, aby sprawdzić wiele odpowiedzi naraz, wprowadźmy pomocnika, nthprimeList/2który wywołuje nthprime/2każdy element z pierwszej listy i umieszcza „wynik” na liście:

nthprimeList([],[]).
nthprimeList([N|TN],[P|TP]):-
    nthprime(N,P),
    nthprimeList(TN,TP).

?- nthprimeList([1,2,3,4,5,6,7,8,9],[P1,P2,P3,P4,P5,P6,P7,P8,P9]).
P1 = 2,
P2 = 3,
P3 = 5,
P4 = 7,
P5 = 11,
P6 = 13,
P7 = 17,
P8 = 19,
P9 = 23;
false.

Answer 2

Korzystając z twoich definicji, definiujemy następujące czynności, aby policzyć i przetestować wszystkie liczby od 2 w górę, jedną po drugiej:

nth_prime(N, Prime):-
  nth_prime(N, Prime, 1, 2).  % 2 is the candidate for 1st prime

nth_prime(N, P, I, Q):-   % Q is I-th prime candidate
  prime(Q) 
  -> ( I = N, P = Q
     ; I1 is I+1, Q1 is Q+1, nth_prime(N, P, I1, Q1) 
     )
  ;  Q1 is Q+1, nth_prime(N, P, I, Q1).

Testowanie:

30 ?- nth_prime(N,P).
N = 1,
P = 2 ;
N = 2,
P = 3 ;
N = 3,
P = 5 ;
N = 4,
P = 7 ;
N = 5,
P = 11 .

31 ?- nth_prime(N,P), N>24.
N = 25,
P = 97 ;
N = 26,
P = 101 ;
N = 27,
P = 103 .

32 ?- nth_prime(N,P), N>99.
N = 100,
P = 541 ;
N = 101,
P = 547 ;
N = 102,
P = 557 .