Jak mogę przetwarzać i analizować wyniki testów porównawczych opublikowane w MSE?
Jak mogę przyjąć wyniki testów porównawczych Mathematica / WL opublikowane na Mathematica Stack Exchange (MSE), takie jak te zamieszczone tutaj ?
Założenia:
Istnieje wiele odpowiedzi z opublikowanymi testami porównawczymi
Wyniki testów porównawczych mają pewną jasną formę „listy reguł”
Widzieć:
Needs["Benchmarking`"]
Benchmark[]
(* {"MachineName" -> "macbook-pro", "System" -> "Mac OS X x86 (64-bit)", "BenchmarkName" -> "WolframMark", "FullVersionNumber" -> "12.1.1", "Date" -> "November 26, 2020",
"BenchmarkResult" -> 3.028, "TotalTime" -> 4.571, "Results" -> {{"Data Fitting", 0.291}, {"Digits of Pi", 0.249}, {"Discrete Fourier Transform", 0.363}, {"Eigenvalues of a Matrix", 0.297},
{"Elementary Functions", 0.375}, {"Gamma Function", 0.356}, {"Large Integer Multiplication", 0.323}, {"Matrix Arithmetic", 0.227}, {"Matrix Multiplication", 0.218}, {"Matrix Transpose", 0.404},
{"Numerical Integration", 0.463}, {"Polynomial Expansion", 0.068}, {"Random Number Sort", 0.449}, {"Singular Value Decomposition", 0.221}, {"Solving a Linear System", 0.267}}} *)
Odpowiedzi
Przyjmowanie pokarmu
Uzyskaj wszystkie odpowiedzi z dyskusji MSE w obiekcie XML:
xmlObject =
Import["https://mathematica.stackexchange.com/questions/234881/benchmarking-with-mathematica-v-12-for-up-to-date-comparision-of-mathematica-acr/235384#235384", "XMLObject"];
Pobierz elementy XML kodu:
lsRes1 = Cases[xmlObject, XMLElement["code", {}, code_] :> code, \[Infinity]];
(Zauważ, że w tym momencie otrzymywane są ciągi kodu).
Usuń Benchmarkpolecenia obliczeniowe i przekonwertuj ciągi kodu na kod WL:
lsRes2 = Map[
ToExpression@
StringReplace[#, {"BenchmarkReport[]" -> "", "Benchmark[]" -> ""}] &, lsRes1];
Length[lsRes2]
(*16*)
Wybierz kod (bloki), które są listami reguł:
lsRes3 = Select[Flatten /@ lsRes2, MatchQ[#, {_Rule ..}] && Length[#] > 1 &];
Length[lsRes3]
(*10*)
Dla każdego bloku kodu spłaszcz metadane i wyniki testów porównawczych w asocjacje:
lsRes4 = Map[Association@ Cases[Flatten[# /. HoldPattern["Results" -> r_] :> (Rule @@@ r)], _Rule] &, lsRes3];
Length[lsRes4]
(*10*)
Upewnij się, że wszystkie skojarzenia mają te same klucze:
lsRes5 =
Block[{lsAllKeys = Union[Flatten[Keys /@ lsRes4]]},
Map[Join[AssociationThread[lsAllKeys, "NA"], #] &, lsRes4]
];
Length[lsRes5]
(*10*)
(W przeciwnym razie uzyskany zestaw danych może być trudny do wykorzystania w niektórych obliczeniach).
Utwórz zestaw danych porównawczych:
dsBenchmarks = Dataset[lsRes5];
dsBenchmarks = dsBenchmarks[SortBy[#BenchmarkResult &]]
Analiza podstawowa
Podsumuj zbiór danych:
ResourceFunction["RecordsSummary"][dsBenchmarks]
Wyniki wykresu (słupki):
Multicolumn@
KeyValueMap[
If[VectorQ[#2, NumericQ],
BarChart[#2, PlotLabel -> #1, PlotTheme -> "Detailed"],
Nothing
] &,
Normal@Transpose@dsBenchmarks
]
Statystyki awarii
Wyniki testu porównawczego podziału na system (lub inne kryteria):
aRes = GroupBy[Normal@dsBenchmarks, #System &, Dataset];
aRes = Map[#[All, Select[#, NumericQ] &] &, aRes];
Oddziel ogólne wyniki testu porównawczego od wyników jego składnika:
aRes2 = Map[#[All, KeyTake[#, {"BenchmarkResult", "TotalTime"}] &] &, aRes];
aRes3 = Map[#[All, KeyDrop[#, {"BenchmarkResult", "TotalTime"}] &] &, aRes];
Pokaż ogólne wyniki testów porównawczych:
aRes2
Pokaż wykresy statystyczne dystrybucji na system:
aResPlots3 =
BoxWhiskerChart[Transpose[Normal[#[Values]]],
PlotLabel -> Row[{"Number of benchmarks:", Spacer[2], Length[#]}],
ChartStyle -> 56, ImageSize -> Medium, PlotTheme -> "Detailed",
ChartLegends -> Keys[Normal@#[[1]]]] & /@ aRes3;
Grid[List @@@ Normal[aResPlots3], Dividers -> All, FrameStyle -> GrayLevel[0.7]]
(Pamiętaj, że musimy zwracać uwagę na liczbę dostępnych testów porównawczych na system. Te liczby są tutaj zbyt małe ...)