Podświetl elementy na liście, używając dopasowania do wzorca

Question

Począwszy od następujących list:

list = {{a, b, c}, {d, e, f}, {g, h, i}, {b, c, d}, {c, a, m}, {c, d, n}};

Chcę wyróżnić elementy, listktórych przecięcie jest większe niż 2.

Poniższy kod nie może uzyskać oczekiwanego wyniku:

list //. 
   {{a___, x:{_, _, _}, b___, y:{_, _, _}, c___} /; 
      Length@Intersection[x, y] >= 2 :> 
         {a, Style[x, Gray], b, Style[y, Gray], c}}

Pożądany wynik to

Rozważałem też Gather, ale to zmieni kolejność na liście.

Zaktualizowano:
wymyśliłem sposób, nie elegancki

list //. {a___,x:({_,_,_}|F[{_,_,_}]),b___,y:({_,_,_}),c___}/;
  Length[Intersection[x/.F->Identity,y]]>=2:>{a,F@x,b,F@y,c}
% /. F->Highlighted

Answer 1

rg = RelationGraph[UnsameQ @ ## && Length@Intersection[##] >= 2 &, list]

hl = VertexList @ EdgeList @ rg

{{a, b, c}, {b, c, d}, {c, a, m}, {c, d, n}}

list /. x : Alternatives @@ hl :> Style[x, Gray] 

list /. x : Alternatives @@ hl :> Highlighted[x, BaseStyle -> Red]

HighlightGraph[rg, hl]

Możesz także użyć ConnectedComponentsi wybrać komponenty z więcej niż 1 wierzchołkiem:

ccs = Select[Length @ # >= 2 &] @ ConnectedComponents[rg]

 {{{a, b, c}, {b, c, d}, {c, a, m}, {c, d, n}}}

list /. x : Alternatives @@ # :> Highlighted[x, BaseStyle -> Red]& /@ ccs

Answer 2

ClearAll[formatList]
formatList[list_] := Module[{rules},
  rules =
    AssociationThread[
      list -> (If[Max[#] >= 2, Gray, Black] & /@ 
        Function[{element}, 
          Length@Intersection[element, #] & /@ 
           Complement[list, {element}]] /@ list)
    ];
  Style[#, rules[#]] & /@ list
]

formatList[list]

Answer 3

Wariant rozwiązania OP, który pozwala uniknąć zagnieżdżania Highlighted:

list //. {a___, x : ({_, _, _} | Highlighted[{_, _, _}, ___]), b___, 
    y : ({_, _, _}), c___} /; Length[Intersection[x /. Highlighted -> (# &), y]] >= 2 :> 
   {a, Highlighted[x /. Highlighted -> (# &)], b, Highlighted@y, c}

To samo podejście przy użyciu Style:

list //. {a___, x : ({_, _, _} | Style[{_, _, _}, ___]), b___, 
    y : ({_, _, _}), c___} /; Length[Intersection[x /. Style -> (# &), y]] >= 2 :> 
   {a, Style[x /. Style -> (# &), Gray], b, Style[y /. Style -> (# &), Gray], c}

Answer 4

Myślę, że najłatwiejszym sposobem jest nadal używanie Gatheri zmiana kolejności indeksu. Tutaj zajmujemy się ogólną sytuacją.

SeedRandom[400];
list = Table[RandomSample[Alphabet[], 3], 40];
newlist = Thread[Range[Length@list] -> list];
result = Gather[newlist, 
   Length[Intersection[Last@#1, Last@#2]] >= 2 &];
keys = Keys /@ result;
keyc = Thread[keys -> RandomColor[Length@keys]]
map[j_] := 
  MapAt[Style[#, Last@keyc[[j]], Bold] &, List /@ First@keyc[[j]]];
fig = Composition[Sequence @@ Table[map[j], {j, 1, Length@keyc}]]@
  list
Grid[Partition[fig, 8], Frame -> All]

Answer 5

list /. x : {__Symbol} /; 
  Max[Length[Intersection[x, #]] & /@ DeleteCases[list, x]] >= 2 :> 
    Style[x, Gray] 

Metoda wykorzystująca GatherBy:

gb = Join @@ Select[Length@# > 1 &]@
   GatherBy[list, Function[x, Max[Length[Intersection[x, #]] & /@ DeleteCases[x][list]]]]

 {{a, b, c}, {b, c, d}, {c, a, m}, {c, d, n}}

list /. x : Alternatives @@ gb :> Style[x, Gray]

Dlaczego Gathernie działa:

Biorąc prostszy przykład:

list2 = Partition[Range@5, 3, 1];
GatherBy[list2, Function[x, Max[Length[Intersection[x, #]] & /@ 
  DeleteCases[x][list2]] >= 2]]

 {{{1, 2, 3}, {2, 3, 4}, {3, 4, 5}}}

Gather[list2, Length[Intersection[##]] >= 2 &]

{{{1, 2, 3}, {2, 3, 4}},
 {{3, 4, 5}}}

Gathernie wykonuje funkcji testu na wszystkich parach listy wejść. Jeśli funkcja test zwraca Truedla pary {p1, p2}(tak, że p1i p2są zgrupowane razem), to para {p1, p3}jest testowana, ale {p2, p3}jest pomijana, jak widać na Tracewyjściu:

Trace[Gather[list2, Length[Intersection[##]] >= 2 &]] // Rest // Rest // Column

Zwróć uwagę, że potrójne {2, 3, 4}i nie{3, 4, 5} są porównywane (ponieważ {2, 3, 4}jest już zebrane }.

Answer 6

Jeszcze innym podejściem jest przyjęcie Union2 podzbiorów, które spełniają warunek:

highlighted = Union @@ Select[Length[Intersection @@ #] >= 2 &] @ Subsets[list, {2}]

{{a, b, c}, {b, c, d}, {c, a, m}, {c, d, n}}

list /. x : Alternatives @@ highlighted :> Style[x, Gray]