Gặp sự cố khi lập bảng lô đất

Question

Vấn đề của tôi rất đơn giản. Tôi đang cố tạo hoạt ảnh với cốt truyện của một hàm. Đây là mã của tôi:

Azul := RGBColor["#19A3CD"]
f[x_] := Piecewise[{{(x - 3)^3 + 2 (x - 3)^2 + 3, 0 <= x <= t}, {0, 
    x > t}}]
funcao := 
 Plot[f[x], {x, -0.6, 5}, PlotStyle -> Thickness[0.006], 
  Background -> Black]

PlotSet := {PlotStyle -> {Thickness[0.006], Azul}, 
  AxesStyle -> Directive[White, Thickness[0.005]], 
  PlotRange -> {-0.2, 6}, 
  Ticks -> {{{1, 1, 0.04}, {2, 2, 0.04}, {3, 3, 0.04}, {4, 4, 
      0.04}, {5, 5, 0.05}}, {{1, 1, 0.04}, {2, 2, 0.04}, {3, 3, 
      0.04}, {4, 4, 0.04}, {5, 5, 0.04}, {6, 6, 0.04}}}, 
  TicksStyle -> 
   Directive[White, Bold, FontSize -> 48, FontColor -> White, 
    FontFamily -> "Montserrat"], ImageSize -> {1920, 1080}}
A := Show[funcao, Axes -> True, Evaluate@PlotSet]
GraficoAnimado = Table[A, {t, 0, 4.5, 0.1}]

Và, lúc ăn xin, các ô đầu tiên trông ổn, như ô này:

Nhưng các âm mưu nexts hoàn toàn mất đi mô hình, như mô hình này:

Và, sau một thời gian, các âm mưu tiếp tục ok.

Tại sao điều này lại xảy ra trên trái đất?

Answer 1

Mã của bạn quá phức tạp và nhiều lỗi. Đây là một cách đơn giản để viết những gì bạn muốn.

Azul = RGBColor["#19A3CD"];
ticks = {#, #, .04} & /@ Range[6];
f[x_] := (x - 3)^3 + 2 (x - 3)^2 + 3
plot[t_] :=
  Plot[f[x], {x, -0.6, t},
    PlotStyle -> Directive[Azul, Thickness[0.006]],
    Background -> Black,
    AxesStyle -> Directive[White, Thickness[0.005]],
    PlotRange -> {{-0.5, 5.1}, {-0.5, 6.2}},
    Ticks -> {Most @ ticks, ticks},
    TicksStyle -> Directive[White, Bold, 48, FontFamily -> "Montserrat"],
    ImageSize -> {1920, 1080}]
GraficoAnimado = Table[plot[t], {t, 0.5, 4.5, 0.1}];

Bảng các ô quá lớn để hiển thị đầy đủ, nhưng đây là các ô đầu tiên, 20 và cuối cùng trông như thế nào.

Magnify[Column[GraficoAnimado[[{1, 20, -1}]], Spacings -> 5], .33]

Answer 2

Phần sau cung cấp cho bạn một trang Manipulatemà bạn có thể chạy một hoạt ảnh.

Manipulate[
 Plot[
  Piecewise[{{(x - 3)^3 + 2 (x - 3)^2 + 3, 0 <= x <= t}, {0, 
     x > t}}],
  {x, -0.6, 5},
  Axes -> True,
  PlotStyle -> {Thickness[0.006], RGBColor["#19A3CD"]},
  AxesStyle -> Directive[White, Thickness[0.005]],
  PlotRange -> {-0.2, 12},
  TicksStyle -> 
   Directive[White, Bold, FontSize -> 10, FontColor -> White, 
    FontFamily -> "Montserrat"], 
  ImageSize -> {1920/4, 1080/4}, Background -> Black
  ],
 {t, 0, 4.5, 0.1}
 ]

HOẶC ... Chỉ cần thay đổi Đầu của phần trên thành Table:

Table[
 Plot[
  Piecewise[{{(x - 3)^3 + 2 (x - 3)^2 + 3, 0 <= x <= t}, {0, 
     x > t}}],
  {x, -0.6, 5},
  Axes -> True,
  PlotStyle -> {Thickness[0.006], RGBColor["#19A3CD"]},
  AxesStyle -> Directive[White, Thickness[0.005]],
  PlotRange -> {-0.2, 12},
  TicksStyle -> 
   Directive[White, Bold, FontSize -> 10, FontColor -> White, 
    FontFamily -> "Montserrat"], 
  ImageSize -> {1920/4, 1080/4}, Background -> Black
  ],
 {t, 0, 4.5, 0.1}
 ]

Mà sẽ cung cấp cho bạn tất cả của cá nhân Plots.

Answer 3

Tôi đang chạy MMA 12.0. Đoạn mã sau, sử dụng các hàm thay vì các biểu thức (Tôi đã làm cho kích thước hình ảnh và phông chữ nhỏ hơn vì tôi không có màn hình XXL).

Azul := RGBColor["#19A3CD"]
f[x_, t_] := 
 Piecewise[{{(x - 3)^3 + 2 (x - 3)^2 + 3, 0 <= x <= t}, {0, x > t}}]
funcao[t_] := 
 Plot[f[x, t], {x, -0.6, 5}, PlotStyle -> Thickness[0.006], 
  Background -> Black]

PlotSet := {PlotStyle -> {Thickness[0.006], Azul}, 
  AxesStyle -> Directive[White, Thickness[0.005]], 
  PlotRange -> {-0.2, 6}, 
  Ticks -> {{{1, 1, 0.04}, {2, 2, 0.04}, {3, 3, 0.04}, {4, 4, 
      0.04}, {5, 5, 0.05}}, {{1, 1, 0.04}, {2, 2, 0.04}, {3, 3, 
      0.04}, {4, 4, 0.04}, {5, 5, 0.04}, {6, 6, 0.04}}}, 
  TicksStyle -> 
   Directive[White, Bold, FontSize -> 4.8, FontColor -> White, 
    FontFamily -> "Montserrat"], ImageSize -> {192, 108}}
A[t_] := Show[funcao[t], Axes -> True, Evaluate@PlotSet]
GraficoAnimado = Table[A[t], {t, 0, 4.5, 0.1}]