Làm cách nào để vẽ một ánh xạ hình cầu từ mặt phẳng z đến mặt phẳng w

Question

Tôi hoàn toàn mới bắt đầu trong Mathematica. Không biết một điều. Tôi cần vẽ một số sơ đồ để hiển thị bản chất phù hợp của bản đồ$w=e^z$.

Tôi cần vẽ một số đường viền trong $z$-máy bay; ví dụ: đường ngang, đường dọc, đường 45 độ và đường tròn đơn vị. Sau đó, tôi cần lấy các đường cong được ánh xạ trong$w$-máy bay ở đâu $u$ và $v$ là chức năng của $x$ và $y$.

Tôi không có ý tưởng làm thế nào để làm điều này? Làm ơn giúp tôi.

Answer 1

Trả lời bình luận.

Sử dụng MeshShadingđể lấp đầy vùng.

expr1 = {x, y};
expr2 = With[{z = x + I*y}, E^z // ReIm // ComplexExpand];
ParametricPlot[#, {x, -4, 4}, {y, -4, 4}, 
    MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
    Mesh -> {{1}, {1}, {0}, {1}}, 
    MeshShading -> {{{{Red, None}, {None, None}}, {{Red, None}, {None,
          None}}}, {{{None, None}, {None, None}}, {{None, 
         None}, {None, None}}}}, 
    MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
       Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
       Opacity[1]}}, Axes -> False, PlotRange -> 4, 
    BoundaryStyle -> None, 
    LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
    PlotStyle -> None] & /@ {expr1, expr2} // GraphicsRow

Đơn giản hóa

expr1 = {x, y};
expr2 = With[{z = x + I*y}, E^z // ReIm // ComplexExpand];
ParametricPlot[#, {x, -4, 4}, {y, -4, 4}, 
    MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
    Mesh -> {{1}, {1}, {0}, {1}}, 
    MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
       Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
       Opacity[1]}}, Axes -> False, PlotRange -> 4, 
    BoundaryStyle -> None, 
    LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
    PlotStyle -> None] & /@ {expr1, expr2} // GraphicsRow

Nguyên

expr = With[{z = x + I*y}, E^z // ReIm // ComplexExpand]
xy = ParametricPlot[{x, y}, {x, -2, 2}, {y, -2, 2}, 
   MeshFunctions -> {#1 &, #2 &, #2 - #1 &, Sqrt[#1^2 + #2^2] &}, 
   Mesh -> {{1}, {1}, {0}, {1}}, 
   MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
      Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
      Opacity[1]}}, PlotPoints -> 50, FrameLabel -> {x, y}, 
   PlotStyle -> None];
uv = ParametricPlot[expr, {x, -4, 4}, {y, -4, 4}, 
   MeshFunctions -> {#3 &, #4 &, #4 - #3 &, Sqrt[#3^2 + #4^2] &}, 
   Mesh -> {{1}, {1}, {0}, {1}}, 
   MeshStyle -> {{Thick, Red, Opacity[1]}, {Thick, Green, 
      Opacity[1]}, {Thick, Blue, Opacity[1]}, {Thick, Yellow, 
      Opacity[1]}}, Axes -> False, PlotRange -> 8, 
   BoundaryStyle -> None, FrameLabel -> {u, v}, 
   LabelStyle -> {FontFamily -> "Times", Blue}, PlotPoints -> 80, 
   PlotStyle -> None];
GraphicsRow[{xy, uv}]